Wolfram Language™

Pokémon Power

The Wolfram Knowledgebase contains information on popular culture icons as well as scientific knowledge. Here, various physical characteristics (attack and defense points, weight, color) of the Pokémon menagerie are explored, contrasted, and visualized using the built-in entity framework.

Plot the distributions of attack and defense points in all Pokémon.

In[1]:=

PairedHistogram[EntityValue["Pokemon", "Attack"], EntityValue["Pokemon", "Defense"], ChartLabels -> {"attack", "defense"}, ChartStyle -> {{LightOrange, LightBlue}, None}]

Out[1]=

Create a Dataset of attack vs. defense points for Generation VI Pokémon and plot them against each other.

In[2]:=

stat = EntityValue[Entity[ "Pokemon", { "Generation" -> Entity[ "PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"}, "Dataset"];

In[3]:=

ListPlot[stat, PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]], AxesLabel -> Automatic, LabelingFunction -> None]

Out[3]=

Compare and plot the average weights of Pokémon over different generations.

In[4]:=

wg = Normal[ GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}], First -> Last, Mean]]

Out[4]=

In[5]:=

BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]], ChartStyle -> 24]

Out[5]=

Use an implicitly defined entity class to find the three heaviest Pokémon.

In[6]:=

EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]

Out[6]=

In[7]:=

EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]; EntityValue[%, "Generation"]

Out[7]=

Use an implicitly defined entity class to find the yellow Pokémon weighing between 50 and 100 kg.

In[8]:=

yellowMidweights = EntityList[ Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{ Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}]]

Out[8]=

Create a collage of these Pokémon characters with sizes based on their weights.

In[9]:=

ImageCollage[ Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}], Background -> White]

Out[9]=

Compare colors of Pokémon in original (Generation I) and newest (Generation VI) groups.

In[10]:=

{color1, color6} = Sort[Tally[EntityValue[EntityList[ Entity["Pokemon", {"Generation" -> Entity["PokemonGeneration", #]}]], "PokedexColor"]]] & /@ {"GenerationI", "GenerationVI"};

In[11]:=

PieChart3D[{color1[[All, 2]], color6[[All, 2]]}, PlotLabel -> "Gen. I (outer) vs. Gen. VI (inner)", ChartElementFunction -> "ProfileSector3D", SectorOrigin -> {Automatic, 1}, ChartStyle -> (color1[[All, 1]] /. co_Entity :> Symbol[co[[2]]]), ChartLegends -> color1[[All, 1]]]

Out[11]=