Compare Periods over Different Domains 

The periodicity properties of a function may differ as it is considered over different domains. The following command compares the period of a function over the integers, reals, and complexes.

In[1]:=

X domains = {Integers, Reals, Complexes};

In[2]:=

X compareDomains[f_, x_] := Table[FunctionPeriod[f, x, dom], {dom, domains}]

Famously, the exponential function has an imaginary period.

In[3]:=

X compareDomains[Exp[x], x]

Out[3]=

Functions can be periodic over the reals only or integers only as well.

In[4]:=

X compareDomains[Sqrt[Cot[x]], x]

Out[4]=

In[5]:=

X compareDomains[Mod[n^2 + 2 n + 3, 7], n]

Out[5]=

show complete Wolfram Language inputhide input

In[6]:=

X Row[{Plot[{Re[Sqrt[Cot[x]]], Im[Sqrt[Cot[x]]]}, {x, 0, 3 Pi}, PlotStyle -> {Thick, Directive[Thick, Dashed]}, Exclusions -> {Pi, 2 Pi}, ColorFunction -> (ColorData[112][Quotient[#, Pi] + 1] &), ColorFunctionScaling -> False, Ticks -> {Automatic, Range[3]}, PlotLegends -> Placed[LineLegend[{Black, Dashed}, {Re[Sqrt[Cot[x]]], Im[Sqrt[Cot[x]]]}, LegendMarkerSize -> 25], Below], PlotRange -> {Automatic, {0, 3}}, ImageSize -> 270], DiscretePlot[Mod[n^2 + 2 n + 3, 7], {n, 21}, ColorFunction -> (ColorData[112][Quotient[# - 1, 7] + 1] &), ImageSize -> 270, ColorFunctionScaling -> False, PlotRange -> {Automatic, {0, 6}}, PlotLegends -> Placed[PointLegend[{White}, {Mod[n^2 + 2 n + 3, 7]}, LegendMarkerSize -> 25], Below]]}]

Out[6]=

On the other hand, power functions involving roots of are periodic over all three domains.

In[7]:=

X compareDomains[I^n, n]

Out[7]=

In[8]:=

X Table[I^n, {n, 0, 8}]

Out[8]=

It is easy to compare the domains for many different functions.

In[9]:=

X funcs = {Exp[x], Sin[x], Cos[Pi x/2], Tanh[3 x], SquareWave[3 x/2], Mod[x, 5], Mod[2 x, 5], Mod[x^2 + 2 x + 3, 7], JacobiDS[x, m], Sqrt[Cot[x]], Sin[ Pi x]^(1/3)};

In[10]:=

X periods = compareDomains[#, x] & /@ funcs

Out[10]=

Nicely format the results.

show complete Wolfram Language inputhide input

In[11]:=

X Grid[Join[{Item[#, Background -> GrayLevel[.9], BaseStyle -> {Bold}] & /@ Prepend[domains, f]}, Join[List[Item[#, Background -> GrayLevel[.9]]] & /@ funcs, periods /. {p_} :> p, 2]], Dividers -> All, ItemSize -> {Automatic, 2}, BaseStyle -> {FontSize -> 16}, Alignment -> {Center, Center}] // TraditionalForm

Out[11]//TraditionalForm=