portfolioData["Technology"] = {"AAPL", "MSFT", "GOOG", "INTC", "CSCO"};

portfolioData["Banking"] = {"JPM", "BAC", "GS", "WFC", "C"};

portfolioData["Food"] = {"MCD", "PEP", "DEO", "HNZ", "GIS"};

portfolioData["Drugs"] = {"MRK", "PFE", "GSK", "SGP", "TEVA"};

portfolioData["Oil"] = {"XOM", "COP", "OXY", "SLB", "RIG"};

sectors = {"Banking", "Technology", "Food", "Drugs", "Oil"};

portfolioData["MarketCap"] = 0;

Function[{sector}, 

   portfolioData[

     "MarketCap"] += (portfolioData[sector, "MarketCap"] = 

      Total[FinancialData[#, "MarketCap"] & /@ 

        portfolioData[sector]])] /@ sectors;

labelStyle[label_] := Style[label, 12, FontFamily -> "Helvetica"]

drilldown[sector_] := 

 PieChart[FinancialData[#, "MarketCap"] & /@ portfolioData[sector], 

  ChartStyle -> 46, 

  ChartLabels -> labelStyle /@ portfolioData[sector], 

  ChartElementFunction -> "PlateauSector"]

chartOptions = {ChartStyle -> "FallColors", 

   ChartLabels -> labelStyle /@ sectors, 

   SectorOrigin -> {{0, 1}, 0.5}, ImageSize -> 500, 

   PlotLabel -> 

    Style["Portfolio Market Capitalization", 

     FontFamily -> "Helvetica", 14], 

   ChartElementFunction -> 

    ChartElementDataFunction["ProfileSector3D", "Profile" -> 5]};

PieChart3D[

  Tooltip[portfolioData[#, "MarketCap"], drilldown[#]] & /@ sectors, 

  chartOptions];