Federal Deposit Insurance Corporation Institutional Data
The Federal Deposit Insurance Corporation (FDIC) is an independent US government agency charged with insuring deposits in US financial institutions. Presently, deposits in member institutions are insured up to $250,000. Here, the holdings, size distribution, and geographic dispersal of member institutions are explored.
First, load an entity store of FDIC data as a ResourceObject.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_216.png)
fdic = ResourceData[
ResourceObject[
Association[
"Name" -> "FDIC Institution EntityStore",
"UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "A Wolfram Language EntityStore with selected \
data on FDIC insured institutions",
"ContentSize" -> Quantity[0, "Bytes"],
"ContentElements" -> {"EntityStore"}]]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_150.png)
Register the store for this session.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_217.png)
PrependTo[$EntityStores, fdic];
Count the number of FDIC institutions.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_218.png)
Length[ents = EntityList["FDICInstitution"]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_151.png)
List some of the available properties of the entity store.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_219.png)
EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_152.png)
Visualize the geographic locations of FDIC-affiliated banks.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_220.png)
GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_153.png)
Display the rank distribution in a log-log plot.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_221.png)
ListLogLogPlot[
Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]],
AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_154.png)
Plot employees vs. assets.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_222.png)
empVsAssets =
EntityValue[
"FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_223.png)
ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_155.png)
Label the six largest institutions.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_156.png)
Plot liabilities vs. assets.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_225.png)
assetsVsLiability =
EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_226.png)
ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_157.png)
Plot net loans and leases vs. total deposits together with a fit.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_227.png)
loanVsDeposit =
EntityValue[
"FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_228.png)
nmf = NonlinearModelFit[
Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &],
c + a x^\[Alpha], {a, \[Alpha], c}, x]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_158.png)
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_229.png)
Show[ListPlot[loanVsDeposit],
Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red,
AxesLabel -> Automatic]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_159.png)
Compare Tier 1 (secure) and Tier 2 capital (riskier) to total assets.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_230.png)
{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@
EntityValue[
"FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital",
"TierTwoRiskBasedCapital"};
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_231.png)
Histogram[{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01},
ChartLegends -> {"Tier 1", "Tier 2"},
PlotLabel -> "Capital/Assets Ratio"]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_160.png)
Retrieve the distribution of assets as an "EntityAssociation".
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_232.png)
dat = EntityValue["FDICInstitution", "TotalAssets",
"EntityAssociation"];
Plot the distribution of assets.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_233.png)
Histogram[dat, "Log", AxesLabel -> Automatic]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_161.png)
Display locations of banks with assets more than 5 billion and 300 billion dollars.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_234.png)
GeoListPlot[
Keys[Select[dat,
GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_162.png)
Graphically discover that the top 10 banks hold more assets than the remaining 6121 combined.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_163.png)
Find banks with the highest 1% of deposits.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_236.png)
dat1 = EntityValue["FDICInstitution", "TotalDeposits",
"EntityAssociation"];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_237.png)
{bottom1percent, top1percent} =
Quantile[values = Values[dat1], {0.01, 0.99}]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_164.png)
Plot them on a map.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_238.png)
GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_165.png)
The distribution of the assets per city fulfills Benford's law to a remarkable degree.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_166.png)
Show banks with the greatest financial leverage.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_242.png)
dataSet3[TakeLargestBy["FinancialLeverage", 10]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_167.png)
Plot the distribution of the financial leverages.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_243.png)
Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5},
PlotLabel -> "FDIC banks Financial Leverage distribution"]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_168.png)
Graphically explore the relationship among assets, long-term assets, and liabilities.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_169.png)