O tom de Shepard: Uma ilusão auditiva
Crie uma ilusão auditiva.
In[1]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_103.png)
range = 12;
duration = 10;
lfoFreq = .05;
basePitch = 30;
numOsc = 8;
midiToFreq[m_] := 2^((m - 69)/12)*440.
Gere rampas para controlar as frequências e amplitudes dos osciladores.
In[2]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_104.png)
phasors =
Table[AudioGenerator[{"Sawtooth", lfoFreq, 2. Pi/numOsc (i - 1.)},
duration, SampleRate -> 500]/2. + .5, {i, numOsc}];
AudioPlot[phasors, PlotLayout -> "Overlaid", PlotRange -> All]
Out[2]=
![](assets.pt-br/shepards-tone-an-auditory-illusion/O_46.png)
Crie frequências que irão controlar os osciladores. As frequências estão afastadas exatamente um oitavo uma das outras e aumentam exponencialmente, de modo que o tom aumente linearmente.
In[3]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_105.png)
freqs = Table[
midiToFreq[(phasors[[i]])*12*numOsc + basePitch], {i, numOsc}];
AudioPlot[freqs, PlotLayout -> "Overlaid", PlotRange -> All]
Out[3]=
![](assets.pt-br/shepards-tone-an-auditory-illusion/O_47.png)
Crie amplitudes que irão controlar os osciladores. As amplitudes chegam a 0 quando as frequências baixam para o valor mínimo.
In[4]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_106.png)
amps = Cos[#*Pi - Pi/2.] & /@ phasors;
AudioPlot[amps, PlotLayout -> "Overlaid", PlotRange -> All]
Out[4]=
![](assets.pt-br/shepards-tone-an-auditory-illusion/O_48.png)
Mostre a relação entre a frequência e a amplitude de um oscilador.
In[5]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_107.png)
AudioPlot[AudioNormalize /@ {freqs[[2]], amps[[2]]}, PlotRange -> All]
Out[5]=
![](assets.pt-br/shepards-tone-an-auditory-illusion/O_49.png)
Combine um banco de osciladores utilizando as frequências e amplitudes criadas.
In[6]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_108.png)
res = Mean[
Table[amps[[i]] AudioGenerator[{"Sin", freqs[[i]]}], {i, numOsc}]]
In[7]:=
![Click for copyable input](assets.pt-br/shepards-tone-an-auditory-illusion/In_109.png)
Spectrogram[res, 8192, 4096, HannWindow,
PlotRange -> {All, {0, 10000}}, ImageSize -> Medium]
Out[7]=
![](assets.pt-br/shepards-tone-an-auditory-illusion/O_50.png)