동향 및 계절성
1949년부터 1960년까지의 항공 여행객 수는 증가하고 있으며, 계절 간의 승객 수의 차이가 나타남을 알수 있습니다. 비 중첩 연간 창문에 Total과 MovingMap을 적용하여 연간 증가를 시각화합니다. 월별 데이터에 DateHistogram를 사용하여 계절 의존성을 조사합니다.
1949년부터 1960년까지의 월별 국제선 여객수는 ExampleData를 사용하여 구할 수있습니다.
In[1]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_56.png)
data = ExampleData[{"Statistics", "InternationalAirlinePassengers"},
"TimeSeries"]
Out[1]=
![](assets.ko/trends-and-seasonalities/O_31.png)
이 데이터는 장기적인 증가 추세와 계절적인 진동을 나타내고 있습니다.
In[2]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_57.png)
DateListPlot[data, PlotTheme -> "Detailed"]
Out[2]=
![](assets.ko/trends-and-seasonalities/O_32.png)
연도별 총계로 세계적인 트렌드를 읽습니다. 총계 결과를 각 년도의 마지막 날에두어 1년의 이동 창을 겹치지 않도록합니다.
In[3]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_58.png)
positionspec = {{1949, 12, 31}, {1960, 12, 31}, Quantity[1, "Year"]};
In[4]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_59.png)
mm = MovingMap[Total,
data, {Quantity[1, "Years"], Right, positionspec}];
In[5]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_60.png)
DateListPlot[mm, PlotMarkers -> Automatic,
GridLines -> {mm["Dates"], None}]
Out[5]=
![](assets.ko/trends-and-seasonalities/O_33.png)
계절 의존성을 분석하고, 여객 수를 날짜 무게로하는 WeightedData를 생성합니다.
In[6]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_61.png)
wd = WeightedData[data["Dates"], data["Values"]];
DateHistogram은 DateReduction에 의해 지정되는 것과 같이 연중 매달 무게를 합계합니다.
In[7]:=
![Click for copyable input](assets.ko/trends-and-seasonalities/In_62.png)
DateHistogram[wd, "Month", DateReduction -> "Year"]
Out[7]=
![](assets.ko/trends-and-seasonalities/O_34.png)