데이터 빈을 사용한 시계열 저장
PoissonProcess의 도착 시간은 독립적이며 ExponentialDistribution을 따릅니다. 지수 분포의 시뮬레이션에 의해 지정된 시간 구간에서 신호를 Databin에 보냄으로써 PoissonProcess의 경로 시뮬레이션을 실행할 수있습니다.
In[1]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_102.png)
SeedRandom["11"];
\[Lambda] = 0.5;
times = RandomVariate[ExponentialDistribution[\[Lambda]], 30];
Databin을 생성합니다.
In[2]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_103.png)
bin = CreateDatabin[]
각각의 시간 간격으로 데이터 빈에 1을 보냅니다.
In[3]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_104.png)
Table[DatabinAdd[bin, <|"arrivals" -> 1|>]; Pause[t], {t, times}];
타임 스탬프가있는 녹음 된 신호를 알아봅니다.
In[4]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_105.png)
TimeSeries[bin]
Out[4]=
![](assets.ko/use-databin-to-store-time-series/O_55.png)
TimeSeries 객체를 추출합니다.
In[5]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_106.png)
ts1 = TimeSeries[bin]["arrivals"]
Out[5]=
![](assets.ko/use-databin-to-store-time-series/O_56.png)
다음의 시계열은 불규칙하게 샘플되어 있습니다.
In[6]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_107.png)
RegularlySampledQ[ts1]
Out[6]=
![](assets.ko/use-databin-to-store-time-series/O_57.png)
TemporalRegularity를 상정하여, Accumulate이 보간을 사용하여 최소의 시간 증분에 대한 시계열을 리샘플링하지 않도록합니다.
In[7]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_108.png)
ts2 = Accumulate[TimeSeries[ts1, TemporalRegularity -> True]]
Out[7]=
![](assets.ko/use-databin-to-store-time-series/O_58.png)
In[8]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_109.png)
DateListStepPlot[ts2, Joined -> False, PlotTheme -> "Detailed"]
Out[8]=
![](assets.ko/use-databin-to-store-time-series/O_59.png)
신호에서 PoissonProcess 매개 변수를 추측하고, 타임 스탬프의 시뮬레이션에 사용 된 ExponentialDistribution 매개 변수와 비교합니다.
In[9]:=
![Click for copyable input](assets.ko/use-databin-to-store-time-series/In_110.png)
{FindProcessParameters[ts2, PoissonProcess[\[Mu]]], \[Lambda]}
Out[9]=
![](assets.ko/use-databin-to-store-time-series/O_60.png)