Fallbeschleunigung schätzen
Die Fallbeschleunigung kann durch die Messung der Schwingungsdauer eines Pendels und dessen Länge
mit der Formel
berechnet werden. Die Messunsicherheit im Durchschnitt von fünf wiederholten Messungen der Schwingungsdauer wird mit BatesDistribution modelliert.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_88.png)
\[Mu]T = Quantity[2, "Seconds"]; \[CapitalDelta]T =
Quantity[0.01, "Seconds"];
period\[ScriptCapitalD] =
BatesDistribution[
5, {\[Mu]T - \[CapitalDelta]T/2, \[Mu]T + \[CapitalDelta]T/2}]
![](assets.de/estimate-acceleration-of-gravity/O_75.png)
Die Länge des Pendulums wurde mit einem Maßstab mit der Auflösung 1 mm gemessen, daher wurde die Messunsicherheit mit UniformDistribution modelliert.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_89.png)
\[Mu]len = Quantity[1, "Meters"]; \[CapitalDelta]len =
UnitConvert[Quantity[1, "mm"], "Meters"];
len\[ScriptCapitalD] =
UniformDistribution[{\[Mu]len - \[CapitalDelta]len/
2., \[Mu]len + \[CapitalDelta]len/2.}]
![](assets.de/estimate-acceleration-of-gravity/O_76.png)
Die Messunsicherheit beim Messen der Fallbeschleunigung.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_90.png)
g\[ScriptCapitalD] =
TransformedDistribution[ (2 \[Pi])^2 len/T^2, {len \[Distributed]
len\[ScriptCapitalD], T \[Distributed] period\[ScriptCapitalD]}]
![](assets.de/estimate-acceleration-of-gravity/O_77.png)
Vergleichen Sie diese mit der linearen Approximation.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_91.png)
lin[e_, {x_, x0_}, {y_, y0_}] :=
Block[{f = Function @@ {{x, y}, e}}, f[x0, y0] +
\!\(\*SuperscriptBox[\(f\),
TagBox[
RowBox[{"(",
RowBox[{"1", ",", "0"}], ")"}],
Derivative],
MultilineFunction->None]\)[x0, y0] (x - x0) +
\!\(\*SuperscriptBox[\(f\),
TagBox[
RowBox[{"(",
RowBox[{"0", ",", "1"}], ")"}],
Derivative],
MultilineFunction->None]\)[x0, y0] (y - y0)]
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_92.png)
lin\[ScriptCapitalD][\[ScriptCapitalD]_] :=
NormalDistribution[Mean[\[ScriptCapitalD]],
StandardDeviation[\[ScriptCapitalD]]]
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_93.png)
gApprox\[ScriptCapitalD] =
TransformedDistribution[
lin[(2 Pi)^2 len/
T^2, {len, \[Mu]len}, {T, \[Mu]T}], {len \[Distributed]
lin\[ScriptCapitalD][len\[ScriptCapitalD]],
T \[Distributed] lin\[ScriptCapitalD][period\[ScriptCapitalD]]}]
![](assets.de/estimate-acceleration-of-gravity/O_78.png)
Berechen Sie die durchschnittliche Fallbeschleunigung mithilfe der exakten und linearisierten Verteilung.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_94.png)
{\[Mu]g, \[Mu]gApprox} = {NExpectation[g,
g \[Distributed] g\[ScriptCapitalD]],
NExpectation[g, g \[Distributed] gApprox\[ScriptCapitalD]]}
![](assets.de/estimate-acceleration-of-gravity/O_79.png)
Berechen Sie die Ausmaße der Messunsicherheit.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_95.png)
{\[Sigma]g, \[Sigma]gApprox} = {Sqrt[
NExpectation[(g - \[Mu]g)^2, g \[Distributed] g\[ScriptCapitalD]]],
StandardDeviation[gApprox\[ScriptCapitalD]]}
![](assets.de/estimate-acceleration-of-gravity/O_80.png)
Ermitteln Sie die Schätzung des Konfidenzintervalls von 90% der gemessenen Beschleunigung.
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_96.png)
confidenceInterval =
Quantile[RandomVariate[g\[ScriptCapitalD], 10^6], {0.05, 0.95}]
![](assets.de/estimate-acceleration-of-gravity/O_81.png)
![Click for copyable input](assets.de/estimate-acceleration-of-gravity/In_97.png)
NProbability[First[confidenceInterval] < x < Last[confidenceInterval],
x \[Distributed] g\[ScriptCapitalD]]
![](assets.de/estimate-acceleration-of-gravity/O_82.png)