Die Zeitgleichung
Aufgrund der Exzentrizität der Erdumlaufbahn und der Neigung der Erdachse in Bezug auf die Ebene der Umlaufbahn variiert die scheinbare Bewegung der Sonne im Laufe des Jahres. Dies bedeutet einen Unterschied zwischen der Zeit, die von einer Sonnenuhr gemessen wird (scheinbare Sonnenzeit) und jener, die von einer präziseren Uhr wie zum Beispiel einer, die auf der scheinbaren Drehung der Erde vor einem Fixsternhintergrund basiert (Sternzeit), gemessen wird. Diese Differenz ist bekannt als die Zeitgleichung.
SiderealTime gibt Werte der Sternzeit mithilfe von MixedUnit als gemischte Einheiten zurück.
![Click for copyable input](assets.de/the-equation-of-time/In_47.png)
SiderealTime[]
![](assets.de/the-equation-of-time/O_43.png)
![Click for copyable input](assets.de/the-equation-of-time/In_48.png)
SiderealTime[];
QuantityUnit[%]
![](assets.de/the-equation-of-time/O_44.png)
Die Sternzeit ist eigentlich ein Winkel und kann daher in andere Winkeleinheiten zerlegt werden.
![Click for copyable input](assets.de/the-equation-of-time/In_49.png)
UnitConvert[SiderealTime[], "AngularDegrees"]
![](assets.de/the-equation-of-time/O_45.png)
Die Zeitgleichung wird durch die Bewegung der Sonne bestimmt, gegeben durch SunPosition. Berechnen Sie die wöchentlichen Werte zu GMT-Mittagszeit.
![Click for copyable input](assets.de/the-equation-of-time/In_50.png)
dates = DateRange[
DateObject[{2015, 1, 1}, TimeObject[{12, 0}, TimeZone -> 0],
TimeZone -> 0.`],
DateObject[{2015, 12, 31}, TimeObject[{12, 0}, TimeZone -> 0],
TimeZone -> 0.`], 7];
![Click for copyable input](assets.de/the-equation-of-time/In_51.png)
sunpos = SunPosition[GeoPosition[{0, 0}], dates,
CelestialSystem -> "Equatorial"]
![](assets.de/the-equation-of-time/O_46.png)
Verwenden Sie SiderealTime, um die Rektaszension am Greenwich-Meridian immer am selben Wochentag zu berechnen.
![Click for copyable input](assets.de/the-equation-of-time/In_52.png)
stime = SiderealTime[GeoPosition[{0, 0}], dates]
![](assets.de/the-equation-of-time/O_47.png)
Ermitteln Sie schließlich die entsprechenden Werte der Zeitgleichung als die Differenz zwischen der Rektaszension der Sonne und der Sternzeit jeweils zu Mittag im Laufe eines Jahres. Drücken Sie das Ergebnis in Minuten aus.
![Click for copyable input](assets.de/the-equation-of-time/In_53.png)
equationoftime =
UnitConvert[(TimeSeriesMap[First, sunpos] - stime),
"MinutesOfRightAscension"]
![](assets.de/the-equation-of-time/O_48.png)
Die absoluten Werte der Zeitgleichung können größer als 15 Minuten sein.
![Click for copyable input](assets.de/the-equation-of-time/In_54.png)
MinMax[equationoftime]
![](assets.de/the-equation-of-time/O_49.png)
![](assets.de/the-equation-of-time/O_50.png)