Visualisez les fonctions propres
Définissez un opérateur de Laplace en 3D.
In[1]:=
![Click for copyable input](assets.fr/visualize-eigenfunctions/In_35.png)
\[ScriptCapitalL] = -Laplacian[u[x, y, z], {x, y, z}];
Précisez des conditions aux limites de Dirichlet homogènes.
In[2]:=
![Click for copyable input](assets.fr/visualize-eigenfunctions/In_36.png)
\[ScriptCapitalB] = DirichletCondition[u[x, y, z] == 0, True];
Trouvez les plus petites valeurs propres et fonctions propres dans une balle.
In[3]:=
![Click for copyable input](assets.fr/visualize-eigenfunctions/In_37.png)
\[CapitalOmega] = Ball[{0, 0, 0}, 2];
{vals, funs} =
DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]},
u[x, y, z], {x, y, z} \[Element] \[CapitalOmega], 2];
In[4]:=
![Click for copyable input](assets.fr/visualize-eigenfunctions/In_38.png)
funs
Out[4]=
![](assets.fr/visualize-eigenfunctions/O_16.png)
Tracez chaque fonction propre en utilisant un tracé de densité 3D.
In[5]:=
![Click for copyable input](assets.fr/visualize-eigenfunctions/In_39.png)
Table[DensityPlot3D[
Evaluate[N[f]], {x, y, z} \[Element] \[CapitalOmega],
PlotTheme -> "NoAxes", PlotLegends -> Placed[Automatic, Below]], {f,
funs}]
Out[5]=
![](assets.fr/visualize-eigenfunctions/O_17.png)
Utilisez des plans de coordonnées pour tracer la densité.
In[6]:=
![Click for copyable input](assets.fr/visualize-eigenfunctions/In_40.png)
Table[SliceDensityPlot3D[
Evaluate[N[f]], {x, y, z} \[Element] \[CapitalOmega],
PlotLegends -> Placed[Automatic, Below]], {f, funs}]
Out[6]=
![](assets.fr/visualize-eigenfunctions/O_18.png)