Differentialgleichungen

Die Wolfram Language findet Lösungen für gewöhnliche, partielle und retardierte Differentialgleichungen (ODEs, PDEs und DDEs).

DSolveValue gibt die allgemeine Lösung einer Differentialgleichung zurück:

(C[1] steht für eine Integrationskonstante .)

In[1]:=

⨯

sol = DSolveValue[y'[x] + y[x] == x, y[x], x]

Out[1]=

Mit /. to kannst du eine Zahl für die Konstante einsetzen.

In[2]:=

⨯

sol /. C[1] -> 1

Out[2]=

Oder du fügst Bedingungen für eine spezielle Lösung hinzu:

In[3]:=

⨯

DSolveValue[{y'[x] + y[x] == x, y[0] == -1}, y[x], x]

Out[3]=

NDSolveValue findet numerische Lösungen:

In[1]:=

⨯

NDSolveValue[{y'[x] == Cos[x^2], y[0] == 0}, y[x], {x, -5, 5}]

Out[1]=

Du kannst diese InterpolatingFunction direkt visualisieren:

In[2]:=

⨯

Plot[%, {x, -5, 5}]

Out[2]=

Um Differentialgleichungssysteme zu lösen, schreibst du am besten alle Gleichungen und Bedingungen in eine Liste:

(Beachte, dass Zeilenumbrüche effektlos sind.)

In[1]:=

⨯

{xsol, ysol} = NDSolveValue[
  {x'[t] == -y[t] - x[t]^2,
   y'[t] == 2 x[t] - y[t]^3,
   x[0] == y[0] == 1},
  {x, y}, {t, 20}]

Out[1]=

Visualisiere die Lösung als parametrische Darstellung:

In[2]:=

⨯

ParametricPlot[{xsol[t], ysol[t]}, {t, 0, 20}]

Out[2]=