Ecuaciones diferenciales

Wolfram Language puede encontrar soluciones a ecuaciones ordinarias, parciales y de retraso (ODE, PDE y DDE).

DSolveValue toma una ecuación diferencia y regresa una solución general:

(C[1] representa una constante de integración.)

In[1]:=

⨯

sol = DSolveValue[y'[x] + y[x] == x, y[x], x]

Out[1]=

Usa /. para remplazar la constante:

In[2]:=

⨯

sol /. C[1] -> 1

Out[2]=

O agrega condiciones para una solución específica:

In[3]:=

⨯

DSolveValue[{y'[x] + y[x] == x, y[0] == -1}, y[x], x]

Out[3]=

NDSolveValue encuentra soluciones numéricas:

In[1]:=

⨯

NDSolveValue[{y'[x] == Cos[x^2], y[0] == 0}, y[x], {x, -5, 5}]

Out[1]=

Puedes representar gráficamente esta función InterpolatingFunction directamente:

In[2]:=

⨯

Plot[%, {x, -5, 5}]

Out[2]=

Para resolver sistemas de ecuaciones diferenciales, incluye todas las ecuaciones y sus condiciones en una lista:

(Nota que los saltos de línea no tienen efecto.)

In[1]:=

⨯

{xsol, ysol} = NDSolveValue[
  {x'[t] == -y[t] - x[t]^2,
   y'[t] == 2 x[t] - y[t]^3,
   x[0] == y[0] == 1},
  {x, y}, {t, 20}]

Out[1]=

Visualiza la solución como una representación gráfica paramétrica:

In[2]:=

⨯

ParametricPlot[{xsol[t], ysol[t]}, {t, 0, 20}]

Out[2]=