New in Wolfram Mathematica 7: New Interface Elements ◄ previous | next ►
Use Arbitrary Layout Primitives in Manipulate
Layout of controls inside Manipulate now supports all 2D layout constructs, including views like OpenerView and TabView.
In[1]:=

Click for copyable input
Manipulate[

 Plot[amp f[freq x], {x, 0, 6}, 

  PlotStyle -> {color, Dashing[dashing], Thickness[thickness]}, 

  Axes -> axes, Frame -> frame, Filling -> filling, 

  AxesOrigin -> axesorigin, PlotLabel -> f],

 

 TabView[{

   "Function" -> Column[{

      Control[{f, {Sin, Cos, Tan}}],

      Control[{freq, 1, 5}],

      Control[{amp, 1, 5}]}],

   "Axes and Frames" -> Column[{

      Control[{axes, {True, False}}],

      Control[{frame, {False, True}}],

      Control[{axesorigin, {0, 0}, {6, 1}}],

      Control[{filling, {None, Axis, Bottom, Top}}]}],

   "Style" -> Column[{

      Control[{color, Blue}],

      Control[{dashing, 0, 0.1}],

      Control[{thickness, 0.001, 0.1}]}]}, 

  ImageSize -> {All, Automatic}]]
Out[1]=