Часы обратного отсчета для нескольких пользователей
Создадим канал, который отображает часы обратного отсчета времени и зададим функцию, которая включает обратный отсчет.
In[1]:=
![Click for copyable input](assets.ru/multi-user-countdown-clock/In_72.png)
CreateChannel["Countdown",
HandlerFunctions ->
Association["MessageReceived" -> ((Countdown`$time = #Message) &)],
Initialization :>
CreateWindow[
DocumentNotebook[{Dynamic[
ClockGauge[$time, PlotTheme -> "Business"]]}],
WindowSize -> All, WindowElements -> {}, ShowCellBracket -> False,
Background -> Black, WindowFrameElements -> {"CloseBox"},
Selectable -> False, WindowTitle -> "Countdown",
CellContext -> "Countdown`"],
Permissions ->
Association["All" -> "Read", "Owner" -> {"Write", "Execute"}]]
Out[1]=
![](assets.ru/multi-user-countdown-clock/O_70.png)
In[2]:=
![Click for copyable input](assets.ru/multi-user-countdown-clock/In_73.png)
countdown[t_] :=
DynamicModule[{paused = True, lbl = "Pause", ii = t, up = None},
Row[{Button[Dynamic[If[paused, "Start", lbl]], paused = ! paused;
up = If[paused, None, UpdateInterval -> 1]],
Dynamic[Refresh[
If[ii >= 0 && ! paused,
" \[LongRightArrow] " <>
TextString[ChannelSend["Countdown", ii--]],
If[ii <= 0, up = None; lbl = "Done"]; ""], up,
TrackedSymbols :> {paused}]]}]]
Подпишимся на данный канал.
In[3]:=
![Click for copyable input](assets.ru/multi-user-countdown-clock/In_74.png)
listener = ChannelListen["Countdown"]
Out[3]=
![](assets.ru/multi-user-countdown-clock/O_71.png)
Установим длительность времени для обратного отсчета (в сек.) и нажмем на кнопку, чтобы начать обратный отсчёт.
In[4]:=
![Click for copyable input](assets.ru/multi-user-countdown-clock/In_75.png)
countdown[20]
Out[4]=
![](assets.ru/multi-user-countdown-clock/O_72.png)
Часы обновляются пока работает обратный отсчет. Обновление можно приостановить, нажав на паузу.
Out[5]=
![](assets.ru/multi-user-countdown-clock/O_73.png)
Другие пользователи могут пользоваться часами для обратного отсчёта, ссылаясь на данный канал в ChannelListen.
In[6]:=
![Click for copyable input](assets.ru/multi-user-countdown-clock/In_76.png)
$WolframID <> ":Countdown"
Out[6]=
![](assets.ru/multi-user-countdown-clock/O_74.png)
In[7]:=
![Click for copyable input](assets.ru/multi-user-countdown-clock/In_77.png)
$WolframID <> ":Countdown";
ChannelListen[%]
Out[7]=
![](assets.ru/multi-user-countdown-clock/O_75.png)