Radio AM
Commencez avec un signal de bande limitée.
In[1]:=
![Click for copyable input](assets.fr/am-radio/In_83.png)
a = BandpassFilter[
AudioNormalize@
AudioResample[Import["ExampleData/rule30.wav"], 96000], {Quantity[
10, "Hertz"], Quantity[5000, "Hertz"]}, 201]
In[2]:=
![Click for copyable input](assets.fr/am-radio/In_84.png)
Periodogram[a, 2000, ImageSize -> Small,
PlotRange -> {{0, 10000}, All}]
Out[2]=
![](assets.fr/am-radio/O_37.png)
Modulez l'amplitude avec une sinusoïde de 22 050 Hz pour déplacer le contenu à l'extrémité supérieure du spectre. Le résultat devrait être déjà inaudible pour la plupart des gens.
In[3]:=
![Click for copyable input](assets.fr/am-radio/In_85.png)
amsignal = ((.5 + a) AudioGenerator[{"Sin", Quantity[22050, "Hertz"]},
Duration@a])/2
In[4]:=
![Click for copyable input](assets.fr/am-radio/In_86.png)
Periodogram[amsignal, 2200, ImageSize -> Small]
Out[4]=
![](assets.fr/am-radio/O_38.png)
Démodulez le signal AM en multipliant le résultat par une sinusoïde à 22 050 Hz avec la même phase.
In[5]:=
![Click for copyable input](assets.fr/am-radio/In_87.png)
result = BandpassFilter[
amsignal*AudioGenerator[{"Sin", Quantity[22050, "Hertz"]},
Duration@amsignal], {Quantity[100, "Hertz"],
Quantity[5000, "Hertz"]}, 201]
Utilisez un filtre non linéaire pour démoduler un signal AM.
In[6]:=
![Click for copyable input](assets.fr/am-radio/In_88.png)
BandpassFilter[# - Mean@# &@
MaxFilter[amsignal, 4], {Quantity[100, "Hertz"],
Quantity[5000, "Hertz"]}, 201]