Finanzmarktentwicklung zum Hören
Importieren Sie Finanzdaten von 1990 bis jetzt.
In[1]:=
![Click for copyable input](assets.de/listen-to-financial-trends/In_91.png)
msft = TimeSeriesRescale[
TimeSeries@
FinancialData["MSFT", {"Jan. 1, 1990", DateString[Now]}], {0, 10}];
aapl = TimeSeriesRescale[
TimeSeries@
FinancialData["AAPL", {"Jan. 1, 1990", DateString[Now]}], {0,
10}];
Resamplen und glätten Sie die Daten.
In[2]:=
![Click for copyable input](assets.de/listen-to-financial-trends/In_92.png)
resampledMSFT =
TimeSeriesResample[Round[MovingAverage[msft, 60]], 1/8];
resampledAAPL =
TimeSeriesResample[Round[MovingAverage[aapl, 60]], 1/8];
ListLinePlot[{resampledMSFT, resampledAAPL},
PlotStyle -> {Automatic, Automatic, PointSize[Large]},
PlotLegends -> {"MSFT", "AAPL"}]
Out[2]=
![](assets.de/listen-to-financial-trends/O_40.png)
Bestimmen Sie eine Funktion, um die Kurse in Frequenzen zu konvertieren.
In[3]:=
![Click for copyable input](assets.de/listen-to-financial-trends/In_93.png)
midiToFreq[m_] := Clip[2^((m - 69)/12)*440., {0, 22050}];
Generieren Sie eine Audiodatei, die von den beiden Zeitreihen bestimmt wird.
In[4]:=
![Click for copyable input](assets.de/listen-to-financial-trends/In_94.png)
res = .8 Mean[{AudioGenerator[{"Sin",
midiToFreq[.5 resampledMSFT + 40]}],
AudioGenerator[{"Triangle", midiToFreq[.5 resampledAAPL + 40]}]}]
In[5]:=
![Click for copyable input](assets.de/listen-to-financial-trends/In_95.png)
Spectrogram[res, 4096, 4096, PlotRange -> {All, {0, 4000}},
ImageSize -> 300]
Out[5]=
![](assets.de/listen-to-financial-trends/O_41.png)