Ein Trip auf einen Blick
Ein Bild kann als eine Datei gespeichert werden, die sowohl Pixeldaten als auch Metainformation enthält. Mit Import können Sie diese Metadaten abrufen und programmierbare Einblicke in den Kontext eines Bildes nehmen.
Importieren und analysieren Sie eine Sammlung von Fotos, die während eines Trips nach Lissabon gemacht wurden.
In[1]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_17.png)
files = Map[img \[Function] ExampleData[img, "FilePath"],
ExampleData[{"TestImageSet", "Lisbon2016"}]];
Sehen Sie sich das Stundenhistogramm der Bilder an.
In[2]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_18.png)
dates = Map[file \[Function] Import[file, "DateTime"], files];
In[3]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_19.png)
DateHistogram[dates, Quantity[1, "Hours"]]
Out[3]=
![](assets.de/a-trip-at-a-glance/O_11.png)
Erstellen Sie eine Collage aus Thumbnails.
In[4]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_20.png)
thumbnails =
ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];
In[5]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_21.png)
ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]
Out[5]=
![](assets.de/a-trip-at-a-glance/O_12.png)
Visualisieren Sie die Fotos auf einer Zeitleiste.
In[6]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_22.png)
TimelinePlot[MapThread[Labeled, {dates, thumbnails}],
PlotLayout -> "Vertical", ImageSize -> Medium]
Out[6]=
![](assets.de/a-trip-at-a-glance/O_13.png)
Fassen Sie alle Informationen in einem Datensatz zusammen.
In[7]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_23.png)
gps = Map[file \[Function] Import[file, "GeoPosition"], files];
In[8]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_24.png)
ds = Dataset[
MapThread[
AssociationThread[{"Thumbnail", "DateTime",
"GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]
Out[8]=
![](assets.de/a-trip-at-a-glance/O_14.png)
Markieren Sie die Standorte, wo Fotos aufgenommen wurden.
In[9]:=
![Click for copyable input](assets.de/a-trip-at-a-glance/In_25.png)
GeoGraphics[
MapThread[
GeoMarker, {Normal[ds[All, "GeoPosition"]],
Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]
Out[9]=
![](assets.de/a-trip-at-a-glance/O_15.png)