Panorama de un viaje
Una imagen puede ser almacenada como un archivo que contenga tanto información de píxeles como meta-información. Usando Import, usted puede obtener tales meta-datos y descubrir información programable acerca del contexto de la imagen.
Importe y analice una colección de fotos tomadas durante una visita a Lisboa.
In[1]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_17.png)
files = Map[img \[Function] ExampleData[img, "FilePath"],
ExampleData[{"TestImageSet", "Lisbon2016"}]];
Vea un histograma de fechas de las imágenes.
In[2]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_18.png)
dates = Map[file \[Function] Import[file, "DateTime"], files];
In[3]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_19.png)
DateHistogram[dates, Quantity[1, "Hours"]]
Out[3]=
![](assets.es/a-trip-at-a-glance/O_11.png)
Vea un collage de vistas en miniatura.
In[4]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_20.png)
thumbnails =
ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];
In[5]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_21.png)
ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]
Out[5]=
![](assets.es/a-trip-at-a-glance/O_12.png)
Presente las fotos en una línea de tiempo.
In[6]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_22.png)
TimelinePlot[MapThread[Labeled, {dates, thumbnails}],
PlotLayout -> "Vertical", ImageSize -> Medium]
Out[6]=
![](assets.es/a-trip-at-a-glance/O_13.png)
Agrupe toda la información en un conjunto de datos.
In[7]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_23.png)
gps = Map[file \[Function] Import[file, "GeoPosition"], files];
In[8]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_24.png)
ds = Dataset[
MapThread[
AssociationThread[{"Thumbnail", "DateTime",
"GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]
Out[8]=
![](assets.es/a-trip-at-a-glance/O_14.png)
Muestre las locaciones donde las imágenes fueron tomadas.
In[9]:=
![Click for copyable input](assets.es/a-trip-at-a-glance/In_25.png)
GeoGraphics[
MapThread[
GeoMarker, {Normal[ds[All, "GeoPosition"]],
Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]
Out[9]=
![](assets.es/a-trip-at-a-glance/O_15.png)