Une visite en un clin d'œil
Une image peut être stockée sous la forme d'un fichier contenant à la fois le contenu des pixels et des méta-informations. En utilisant Import, vous pouvez obtenir ces métadonnées et découvrir des informations programmables sur le contexte d'une photo.
Importez et analysez une collection de photos prises lors d'une visite à Lisbonne.
In[1]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_17.png)
files = Map[img \[Function] ExampleData[img, "FilePath"],
ExampleData[{"TestImageSet", "Lisbon2016"}]];
Affichez l'histogramme de la date des images.
In[2]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_18.png)
dates = Map[file \[Function] Import[file, "DateTime"], files];
In[3]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_19.png)
DateHistogram[dates, Quantity[1, "Hours"]]
Out[3]=
![](assets.fr/a-trip-at-a-glance/O_11.png)
Affichez un collage de vignettes.
In[4]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_20.png)
thumbnails =
ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];
In[5]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_21.png)
ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]
Out[5]=
![](assets.fr/a-trip-at-a-glance/O_12.png)
Présentez les photos sur une ligne chronologique..
In[6]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_22.png)
TimelinePlot[MapThread[Labeled, {dates, thumbnails}],
PlotLayout -> "Vertical", ImageSize -> Medium]
Out[6]=
![](assets.fr/a-trip-at-a-glance/O_13.png)
Rassemblez toutes les informations dans un jeu de données.
In[7]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_23.png)
gps = Map[file \[Function] Import[file, "GeoPosition"], files];
In[8]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_24.png)
ds = Dataset[
MapThread[
AssociationThread[{"Thumbnail", "DateTime",
"GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]
Out[8]=
![](assets.fr/a-trip-at-a-glance/O_14.png)
Affichez les lieux où les images ont été prises.
In[9]:=
![Click for copyable input](assets.fr/a-trip-at-a-glance/In_25.png)
GeoGraphics[
MapThread[
GeoMarker, {Normal[ds[All, "GeoPosition"]],
Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]
Out[9]=
![](assets.fr/a-trip-at-a-glance/O_15.png)