Сколько это весит?
Вес объекта в гравитационном поле является произведением его массы и значением гравитационного поля в положении объекта. Гравитационное поле не является постоянным на поверхности Земли, поэтому один и тот же объект имеет различную массу в различных положениях.
Данный пример изучает изменения масштаба гравитационного поля с высотой и широтой.
GeogravityModelData рассчитывает несколько свойств гравитационного поля Земли в заданном положении.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_98.png)
GeogravityModelData[GeoPosition[{0, 0}]]
![](assets.ru/how-much-does-it-weigh/O_81.png)
А также использует топографическую высоту, предоставленную GeoElevationData.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_99.png)
GeoElevationData[GeoPosition[{0, 0}]]
![](assets.ru/how-much-does-it-weigh/O_82.png)
Если не принимать во внимание другие факторы, то гравитационное поле обычно меньше для положения со схожей широтой, но большей высотой.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_100.png)
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
![](assets.ru/how-much-does-it-weigh/O_83.png)
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_101.png)
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]];
{GeoElevationData[%, UnitSystem -> "Metric"],
GeogravityModelData[%, "Magnitude"]}
![](assets.ru/how-much-does-it-weigh/O_84.png)
Рассчитайте значения гравитационного поля Земли на равноудалённых точках на экваторе.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_102.png)
equatorialgravity =
GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]},
"Magnitude"][[1]]
![](assets.ru/how-much-does-it-weigh/O_85.png)
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_103.png)
ListPlot[equatorialgravity, Joined -> True]
![](assets.ru/how-much-does-it-weigh/O_86.png)
В предложенной гистограмме Вы найдёте две главные вершины, соответствующие земным областям и дну океанов.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_104.png)
Histogram[equatorialgravity, 20]
![](assets.ru/how-much-does-it-weigh/O_87.png)
Наложите масштаб гравитационного поля на рельефную карту Земли.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_105.png)
equatorialgravityplot =
ListPlot[equatorialgravity, Axes -> False, Joined -> True,
AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None,
ImageSize -> 400, PlotStyle -> Red];
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_106.png)
worldmap =
GeoGraphics[GeoPath["Equator"], GeoRange -> "World",
ImageSize -> 400, GeoBackground -> "ReliefMap"];
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_107.png)
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
![](assets.ru/how-much-does-it-weigh/O_88.png)
С целью демонстрации изменений широты найдите среднее значение гравитационного поля по отношению к долготе и представьте результат в отношении широты.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_108.png)
gravity =
Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}],
GeoPosition[{90, 180}]}, "Magnitude"];
Антарктика находится под очевидным влиянием низких широт из-за дополнительной высоты.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_109.png)
ListPlot[gravity, DataRange -> {-90, 90}]
![](assets.ru/how-much-does-it-weigh/O_89.png)
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_110.png)
MinMax[gravity]
![](assets.ru/how-much-does-it-weigh/O_90.png)
Таким образом, отклонения в весе определённого объекта могут достигать порядка 0.5% в зависимости от места измерения.
![Click for copyable input](assets.ru/how-much-does-it-weigh/In_111.png)
MinMax[gravity];
1 - First[%]/Last[%]