Sphärische oder ellipsoide Mercator-Projektion
Die Mercator-Projektion erzeugt unterschiedliche Resultate, je nachdem, ob ein Kugelmodell oder ein Ellipsoidmodell der Erde verwendet wird. Die Wolfram Language ermöglicht es Ihnen, mit beiden Varianten zu arbeiten.
In[1]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_74.png)
webMercator = {"Mercator",
"ReferenceModel" -> GeodesyData["WGS84", "SemimajorAxis"]}
Out[1]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_61.png)
In[2]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_75.png)
ellipMercator = {"Mercator", "ReferenceModel" -> "WGS84"}
Out[2]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_62.png)
Transformieren Sie den Standort der University of Oxford mit beiden Projektionen.
In[3]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_76.png)
p = GeoPosition[
Entity["University", "UniversityOfOxfordUnitedKingdom36022"]]
Out[3]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_63.png)
In[4]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_77.png)
GeoGridPosition[p, webMercator][[1]]
Out[4]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_64.png)
In[5]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_78.png)
GeoGridPosition[p, ellipMercator][[1]]
Out[5]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_65.png)
Es gibt eine vertikale Differenz, die auf der Karte mehr als 33 Kilometern entspricht.
In[6]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_79.png)
GeoGridPosition[p, webMercator][[1]];
GeoGridPosition[p, ellipMercator][[1]];
%% - %
Out[6]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_66.png)
Erzeugen Sie Karten des Vereinigten Königreichs und Irlands auf Grundlage eines Kugel- und eines Ellipsoidmodells. Sie sehen fast identisch aus.
In[7]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_80.png)
webmap = GeoGraphics[{FaceForm[], EdgeForm[Red],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Red, Point[p]},
GeoProjection -> webMercator, GeoBackground -> None][[1]]
Out[7]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_67.png)
In[8]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_81.png)
ellipmap =
GeoGraphics[{FaceForm[], EdgeForm[Blue],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Blue, Point[p]},
GeoProjection -> ellipMercator, GeoBackground -> None][[1]]
Out[8]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_68.png)
Wenn sie jedoch übereinandergelegt werden, sieht man den Unterschied ganz deutlich.
In[9]:=
![Click for copyable input](assets.de/spherical-or-ellipsoidal-mercator/In_82.png)
Show[webmap, ellipmap]
Out[9]=
![](assets.de/spherical-or-ellipsoidal-mercator/O_69.png)