Encontre os parâmetros ideais de um classificador
Carregue um conjunto de dados e divida em um conjunto de treinamento e um conjunto de teste.
In[1]:=
![Click for copyable input](assets.pt-br/find-the-optimal-parameters-of-a-classifier/In_36.png)
data = RandomSample[
ExampleData[{"MachineLearning", "Titanic"}, "Data"]
];
training = data[[;; 1000]];
test = data[[1001 ;;]];
Defina uma função que calcule o desempenho de um classificador como uma função dos seus (hiper) parâmetros .
In[2]:=
![Click for copyable input](assets.pt-br/find-the-optimal-parameters-of-a-classifier/In_37.png)
loss[{c_, gamma_, b_, d_}] := -ClassifierMeasurements[
Classify[training,
Method -> {"SupportVectorMachine",
"KernelType" -> "Polynomial",
"SoftMarginParameter" -> Exp[c],
"GammaScalingParameter" -> Exp[gamma],
"BiasParameter" -> Exp[b],
"PolynomialDegree" -> d }
], test, "LogLikelihoodRate"];
Defina o valor possível dos parâmetros.
In[3]:=
![Click for copyable input](assets.pt-br/find-the-optimal-parameters-of-a-classifier/In_38.png)
region = ImplicitRegion[And[
-3. <= c <= 3.,
-3. <= gamma <= 3. ,
-1. <= b <= 2.,
1 <= d <= 3 ,
d \[Element] Integers],
{ c, gamma, b, d}]
Out[3]=
![](assets.pt-br/find-the-optimal-parameters-of-a-classifier/O_29.png)
Procure um bom conjunto de parâmetros.
In[4]:=
![Click for copyable input](assets.pt-br/find-the-optimal-parameters-of-a-classifier/In_39.png)
bmo = BayesianMinimization[loss, region]
Out[4]=
![](assets.pt-br/find-the-optimal-parameters-of-a-classifier/O_30.png)
In[5]:=
![Click for copyable input](assets.pt-br/find-the-optimal-parameters-of-a-classifier/In_40.png)
bmo["MinimumConfiguration"]
Out[5]=
![](assets.pt-br/find-the-optimal-parameters-of-a-classifier/O_31.png)
Treine um classificador com esses parâmetros.
In[6]:=
![Click for copyable input](assets.pt-br/find-the-optimal-parameters-of-a-classifier/In_41.png)
Classify[training,
Method -> {"SupportVectorMachine",
"KernelType" -> "Polynomial",
"SoftMarginParameter" -> Exp[2.979837222482109`],
"GammaScalingParameter" -> Exp[-2.1506497693543025`],
"BiasParameter" -> Exp[-0.9038364134482837`],
"PolynomialDegree" -> 2}
]
Out[6]=
![](assets.pt-br/find-the-optimal-parameters-of-a-classifier/O_32.png)