Visualisez et analysez les structures anatomiques
Tracez la structure osseuse et la peau d'un pied humain et calculez sa surface (en millimètres carrés).
In[1]:=
![Click for copyable input](assets.fr/visualize-and-analyze-anatomical-structures/In_1.png)
Row[EntityValue[{Entity["AnatomicalStructure", "RightFoot"],
Entity["AnatomicalStructure", "SkinOfRightFoot"]}, "MeshRegion"]]
Out[1]=
![](assets.fr/visualize-and-analyze-anatomical-structures/O_1.png)
In[2]:=
![Click for copyable input](assets.fr/visualize-and-analyze-anatomical-structures/In_2.png)
Area[EntityValue[Entity["AnatomicalStructure", "SkinOfRightFoot"],
"MeshRegion"]]
Out[2]=
![](assets.fr/visualize-and-analyze-anatomical-structures/O_2.png)
Tracez la connectivité des branches distales de l'artère brachiale.
In[3]:=
![Click for copyable input](assets.fr/visualize-and-analyze-anatomical-structures/In_3.png)
NestGraph[Cases[EntityValue[#, "Branches"], _Entity] &,
Entity["AnatomicalStructure", "BrachialArtery"], 3,
VertexLabels -> Placed["Name", Tooltip], EdgeStyle -> Pink,
VertexStyle -> Pink, GraphStyle -> "BasicBlack"]
Out[3]=
![](assets.fr/visualize-and-analyze-anatomical-structures/O_3.png)
Trouvez les parties de l'avant-bras gauche.
In[4]:=
![Click for copyable input](assets.fr/visualize-and-analyze-anatomical-structures/In_4.png)
g = NestGraph[Cases[EntityValue[#, "ConstitutionalParts"], _Entity] &,
Entity["AnatomicalStructure", "LeftForearm"], 2]
Out[4]=
![](assets.fr/visualize-and-analyze-anatomical-structures/O_4.png)
Calculez la longueur combinée du pharynx, de l'œsophage, de l'estomac, de l'intestin grêle et du gros intestin.
In[5]:=
![Click for copyable input](assets.fr/visualize-and-analyze-anatomical-structures/In_5.png)
UnitConvert[
EntityValue[
EntityGroup[{Entity["AnatomicalStructure", "Pharynx"],
Entity["AnatomicalStructure", "Esophagus"],
Entity["AnatomicalStructure", "Stomach"],
Entity["AnatomicalStructure", "SmallIntestine"],
Entity["AnatomicalStructure", "LargeIntestine"]}],
"Length"], "Metric"]
Out[5]=
![](assets.fr/visualize-and-analyze-anatomical-structures/O_5.png)
Comparez la longueur et la largeur du pied chez les hommes et les femmes.
In[6]:=
![Click for copyable input](assets.fr/visualize-and-analyze-anatomical-structures/In_6.png)
# -> (UnitConvert[#, "Centimeters"] & /@
EntityValue[
EntityInstance[Entity["AnatomicalStructure", "Foot"],
"Gender" -> #], {"Length", "Width"},
"PropertyAssociation"]) & /@ {"Female", "Male"}
Out[6]=
![](assets.fr/visualize-and-analyze-anatomical-structures/O_6.png)