Klassifizierung von Ziffern
Verwenden Sie die MNIST-Datenbank handgeschriebener Ziffern, um ein Convolutional Neural Network zur Vorhersage von Ziffern auf einem Bild zu trainieren.
Erstellen Sie als ersten Schritt die Trainingsdaten und Validierungsdaten.
In[1]:=
![Click for copyable input](assets.de/digit-classification/In_1.png)
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];
In[2]:=
![Click for copyable input](assets.de/digit-classification/In_2.png)
RandomSample[trainingData, 5]
Out[2]=
![](assets.de/digit-classification/O_1.png)
Bestimmen Sie ein Convolutional Neural Network, das 28×28-Graustufenbilder als Input erhält.
In[3]:=
![Click for copyable input](assets.de/digit-classification/In_3.png)
lenet = NetChain[
{ConvolutionLayer[20, 5], Ramp, PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp, PoolingLayer[2, 2], FlattenLayer[],
500, Ramp, 10, SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]
Out[3]=
![](assets.de/digit-classification/O_2.png)
Trainieren Sie das Netzwerk vier Trainingsrunden lang.
In[4]:=
![Click for copyable input](assets.de/digit-classification/In_4.png)
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3];
Out[5]=
![](assets.de/digit-classification/O_3.png)
Testen Sie das trainierte Netzwerk direkt mit zufällig ausgewählten Bildern aus dem Validierungssatz.
In[6]:=
![Click for copyable input](assets.de/digit-classification/In_5.png)
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]
Out[6]=
![](assets.de/digit-classification/O_4.png)