数字の分類
手書き数字のMNISTデータベースを使って,画像で与えられた数字を予測するたたみ込みネットワークを訓練する.
訓練データと検証データを取得する.
In[1]:=
![Click for copyable input](assets.ja/digit-classification/In_1.png)
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];
In[2]:=
![Click for copyable input](assets.ja/digit-classification/In_2.png)
RandomSample[trainingData, 5]
Out[2]=
![](assets.ja/digit-classification/O_1.png)
入力として28×28のグレースケール画像を取るたたみ込みニューラルネットワークを定義する.
In[3]:=
![Click for copyable input](assets.ja/digit-classification/In_3.png)
lenet = NetChain[
{ConvolutionLayer[20, 5], Ramp, PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp, PoolingLayer[2, 2], FlattenLayer[],
500, Ramp, 10, SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]
Out[3]=
![](assets.ja/digit-classification/O_2.png)
3回の訓練ラウンドでネットワークを訓練する.
In[4]:=
![Click for copyable input](assets.ja/digit-classification/In_4.png)
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3];
Out[5]=
![](assets.ja/digit-classification/O_3.png)
検証集合からランダムに抽出された画像で,訓練されたネットワークを直接評価する.
In[6]:=
![Click for copyable input](assets.ja/digit-classification/In_5.png)
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]
Out[6]=
![](assets.ja/digit-classification/O_4.png)