Изучение параметризации многообразия
Изучите параметризацию многообразия, к которой относятся входные данные, используя автокодировщик, сеть с узким слоем, изучающим реконструкцию первичного ввода.
Пример данных режима обучения из части синтезированного двумерного многообразия.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_27.png)
manifold =
Table[AngleVector[{x, 0.9 Pi x}] +
x/20*RandomVariate[NormalDistribution[], 2], {x, 0, 1, 0.001}];
plot = ListPlot[manifold, PlotStyle -> Orange]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_22.png)
Создайте сеть с узким слоем для изучения параметризации многообразия.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_28.png)
net = NetChain[{25, Ramp, 1, 25, Ramp, 2}, "Input" -> 2]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_23.png)
Создайте сеть потерь, которая рассчитывает потери, основанные на "ошибке восстановления" - измерение степени, до которой сеть может производить выход идентичный вводу.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_29.png)
lossNet =
NetGraph[{net, MeanSquaredLossLayer[]}, {1 -> 2,
NetPort["Input"] -> NetPort[2, "Target"]}]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_24.png)
Обучите сеть потерь на многообразии и выявите начальную сеть из сети потерь.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_30.png)
lossNet =
NetTrain[lossNet, <|"Input" -> manifold|>, BatchSize -> 4096];
trained = NetExtract[lossNet, 1];
Визуализируйте, как сеть проектирует произвольные точки на многообразие.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_31.png)
{{xmin, xmax}, {ymin, ymax}} = CoordinateBounds[manifold, .2];
Show[plot,
StreamPlot[
trained[{x, y}] - {x, y}, {x, xmin, xmax}, {y, ymin, ymax}]]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_25.png)
Разделите сеть на сеть кодировщика и декодера (кодировщик параметризует точки, используя одиночную скалярную величину, в то время как декодер восстанавливает точку из параметризации).
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_32.png)
decoder = Drop[trained, 3]
encoder = Take[trained, 3]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_26.png)
![](assets.ru/learn-a-parameterization-of-a-manifold/O_27.png)
Раскрасьте каждую точку в оригинальном многообразии согласно её параметризации в кодировщике.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_33.png)
ListPlot[Style[#, Hue[First[0.3 + encoder[#]]/3]] & /@ manifold]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_28.png)
Получите диапазон параметризации путём применения кодировщика к многообразию.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_34.png)
{min, max} = MinMax[encoder[manifold]]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_29.png)
Изобразите восстановление в этом диапазоне наряду с оригинальным многообразием.
![Click for copyable input](assets.ru/learn-a-parameterization-of-a-manifold/In_35.png)
Show[plot, ListLinePlot[Table[decoder[x], {x, min, max, .01}]]]
![](assets.ru/learn-a-parameterization-of-a-manifold/O_30.png)