복소 해석 함수 구축
축 실수와 허수 부분의 값에서 시작하여 복소 해석 함수를 구축합니다.
실수와 허수 부인 u와 v는, 코시-리만 방정식을 만족시킵니다.
In[1]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_118.png)
creqns = {D[u[x, y], x] == D[v[x, y], y],
D[v[x, y], x] == -D[u[x, y], y]};
축에 u와 v의 값을 규정합니다.
In[2]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_119.png)
xvals = {u[x, 0] == x^3, v[x, 0] == 0};
코시-리만 방정식을 풉니다.
In[3]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_120.png)
sol = DSolve[{creqns, xvals}, {u, v}, {x, y}]
Out[3]=
![](assets.ko/construct-a-complex-analytic-function/O_58.png)
솔루션이 조화 함수임을 확인합니다.
In[4]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_121.png)
Laplacian[{u[x, y], v[x, y]} /. sol[[1]], {x, y}]
Out[4]=
![](assets.ko/construct-a-complex-analytic-function/O_59.png)
솔루션에 의해 생성된 유선과 등위를 시각화합니다.
In[5]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_122.png)
ContourPlot[{u[x, y], v[x, y]} /. sol[[1]], {x, -5, 5}, {y, -5, 5},
ContourStyle -> {Red, Blue}]
Out[5]=
![](assets.ko/construct-a-complex-analytic-function/O_60.png)
솔루션에서 해석 함수를 구축합니다.
In[6]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_123.png)
f[x_, y_] = u[x, y] + I v[x, y] /. sol[[1]]
Out[6]=
![](assets.ko/construct-a-complex-analytic-function/O_61.png)
다음은 함수 을 나타냅니다.
In[7]:=
![Click for copyable input](assets.ko/construct-a-complex-analytic-function/In_124.png)
(f[x, y] // Factor) /. {x + I y -> z}
Out[7]=
![](assets.ko/construct-a-complex-analytic-function/O_62.png)