Наблюдение за квантовой частицей в двухмерном прямоугольнике
Квантовая частица, свободно передвигающаяся в двухмерном прямоугольнике со сторонами xMax и yMax, описана двухмерным динамичным уравнением Шрёдингера, а также граничными условиями, которые заставляют волновую функцию стремится к нулю на границе.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_92.png)
eqn = I D[\[Psi][x, y, t], t] == -\[HBar]^2/(2 m)
Laplacian[\[Psi][x, y, t], {x, y}];
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_93.png)
bcs = {\[Psi][0, y, t] == 0, \[Psi][xMax, y, t] ==
0, \[Psi][x, yMax, t] == 0, \[Psi][x, 0, t] == 0};
Уравнение имеет общее решение, которое является формальной бесконечной суммой так называемых собственных состояний.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_94.png)
DSolveValue[{eqn, bcs}, \[Psi][x, y, t], {x, y, t}]
![](assets.ru/observe-a-quantum-particle-in-a-box/O_43.png)
Определить начальное условие, которое равно цельному собственному состоянию.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_95.png)
initEigen = \[Psi][x, y, 0] ==
2 /Sqrt[xMax yMax] Sin[(\[Pi] x)/xMax] Sin[(\[Pi] y)/yMax];
В данном случае, решением является простое динамичное кратное число (модулей единиц измерения) начального условия.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_96.png)
DSolveValue[{eqn, bcs, initEigen}, \[Psi][x, y, t], {x, y, t}]
![](assets.ru/observe-a-quantum-particle-in-a-box/O_44.png)
Определить начальное условие, которое является суммой собственных состояний. Поскольку начальные условия не являются собственным состоянием, вероятная плотность положения частицы будет зависеть от времени.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_97.png)
initSum = \[Psi][x, y, 0] ==
Sqrt[2]/Sqrt[
xMax yMax] (Sin[(2 \[Pi] x)/xMax] Sin[(\[Pi] y)/yMax] +
Sin[(\[Pi] x)/xMax] Sin[(3 \[Pi] y)/yMax]);
Решить с новым начальным условием.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_98.png)
sol = DSolveValue[{eqn, bcs, initSum}, \[Psi][x, y, t], {x, y, t}]
![](assets.ru/observe-a-quantum-particle-in-a-box/O_45.png)
Рассчитать плотность вероятности, вводя значения уменьшенной константы Планка, массы электрона и двухмерного прямоугольникa атомных масштабов с использованием единиц измерения массы электрона, таких как нанометры и фемтосекунды.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_99.png)
\[HBar] =
QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"],
"ElectronMass" * ("Nanometers")^2/"Femtoseconds"]
![](assets.ru/observe-a-quantum-particle-in-a-box/O_46.png)
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_100.png)
\[Rho][x_, y_, t_] =
FullSimplify[ComplexExpand[Conjugate[sol] sol]] /. {m -> 1,
xMax -> 1, yMax -> 1}
![](assets.ru/observe-a-quantum-particle-in-a-box/O_47.png)
Визуализировать плотность вероятности внутри двухмерного прямоугольникa с течением времени.
![Click for copyable input](assets.ru/observe-a-quantum-particle-in-a-box/In_101.png)
ListAnimate[
Table[Plot3D[\[Rho][x , y , t], {x, 0, 1}, {y, 0, 1},
PlotTheme -> {"Scientific", "SolidGrid"}, AxesLabel -> {"\!\(\*
StyleBox[\"x\", \"SO\"]\) (nm)", " \!\(\*
StyleBox[\"y\", \"SO\"]\) (nm)", "\!\(\*
StyleBox[\"\[Rho]\", \"SO\"]\) (\!\(\*SuperscriptBox[\(nm\), \
\(-2\)]\))"}, ImageSize -> Medium, PlotRange -> {0, 7}], {t, 0,
19, .5}]]
![](assets.ru/observe-a-quantum-particle-in-a-box/swf_6.png)