自由格式实体-属性查询
用 Interpreter 构建与 EntityValue 类似的函数,但允许 EntityType、 Entity 和 EntityProperty 的自由语言描述.
In[1]:=
![Click for copyable input](assets.zh/free-form-entity-property-queries/In_322.png)
NLEntityValue[type_String, entity_String, property_String] :=
With[{res =
Map[{Replace[#, AmbiguityList[{a___}, ___] :> a]} &,
Interpreter[
CompoundElement[{"EntityType", "Entity", "EntityProperty"}],
AmbiguityFunction -> All][{type, entity, property}]]},
If[FreeQ[res, Failure],
EntityValue[FirstCase[res[[2]], Entity[res[[1, 1]], ___]],
FirstCase[res[[3]], EntityProperty[res[[1, 1]], ___]]],
Missing["Unknown"]]]
将函数应用于不同的实体类、实体和属性.
In[2]:=
![Click for copyable input](assets.zh/free-form-entity-property-queries/In_323.png)
NLEntityValue["country", "GB", "oil imports"]
Out[2]=
![](assets.zh/free-form-entity-property-queries/O_209.png)
In[3]:=
![Click for copyable input](assets.zh/free-form-entity-property-queries/In_324.png)
NLEntityValue["city", "windy city", "elderly population"]
Out[3]=
![](assets.zh/free-form-entity-property-queries/O_210.png)
In[4]:=
![Click for copyable input](assets.zh/free-form-entity-property-queries/In_325.png)
NLEntityValue["celebrity", "the Boss", "birthday"]
Out[4]=
![](assets.zh/free-form-entity-property-queries/O_211.png)
In[5]:=
![Click for copyable input](assets.zh/free-form-entity-property-queries/In_326.png)
NLEntityValue["moon", "ganymede", "image"]
Out[5]=
![](assets.zh/free-form-entity-property-queries/O_212.png)
In[6]:=
![Click for copyable input](assets.zh/free-form-entity-property-queries/In_327.png)
Row[NLEntityValue["popular curve", #, "image"] & /@ {"trump",
"hillary clinton"}]
Out[6]=
![](assets.zh/free-form-entity-property-queries/O_213.png)