Museum of Modern Art Paintings and Artists
The Museum of Modern Art (MoMA) maintains a public dataset at https://github.com/MuseumofModernArt/collection containing detailed information on its holdings. Here, you can make use of a custom entity store derived from this data to study the dimensions of MoMA paintings, as well as to investigate the longevity of their artists.
First, load the prebuilt entity store from a ResourceObject.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_164.png)
momaStore = ResourceData[
ResourceObject[
Association[
"Name" -> "Museum of Modern Art Holdings and Artists",
"UUID" -> "38f47cc0-667d-4988-8ebe-6c1bef23fdc6",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "Holdings and artists of The Museum of Modern \
Art", "ContentSize" -> Association["EntityStore" -> 0],
"ContentElements" -> {"EntityStore"}]]]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_118.png)
Register the store for this session.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_165.png)
PrependTo[$EntityStores, momaStore];
Obtain a list of artwork properties from the entity store using the "MoMAHolding" entity type.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_166.png)
EntityProperties["MoMAHolding"]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_119.png)
List representative property values for a particular piece.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_167.png)
DeleteMissing[
EntityValue[Entity["MoMAHolding", "79802"],
"PropertyAssociation" ]] // Take[#, 15] &
![](assets.en/museum-of-modern-art-paintings-and-artists/O_120.png)
Make a date histogram of the completion dates of all works at MoMA.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_168.png)
DateHistogram[
DeleteMissing[EntityValue["MoMAHolding", "CompletionDate"]]]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_121.png)
Tally the types of works in the collection.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_169.png)
TextGrid[SortBy[
Tally[EntityValue["MoMAHolding",
EntityProperty["MoMAHolding", "Classification"]]], Last] //
Reverse, Dividers -> All,
Background -> {Automatic, {{LightBlue, None}}},
Alignment -> {{Left, Decimal}, Automatic}]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_122.png)
Use implicitly defined entity classes to retrieve MoMA paintings.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_170.png)
paintings =
EntityClass[
"MoMAHolding", {EntityProperty["MoMAHolding", "Classification"] ->
"Painting"}];
Plot histograms of painting aspect ratios and areas. At default binning width, the distribution of aspect ratios appears to be trimodal.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_171.png)
Table[Histogram[EntityValue[paintings, prop],
PlotLabel ->
prop], {prop, {EntityProperty["MoMAHolding", "AspectRatio"],
EntityProperty["MoMAHolding", "Area"]}}]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_123.png)
Now obtain a list of properties associated with artists using the "MoMAArtist" entity type.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_172.png)
EntityProperties["MoMAArtist"]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_124.png)
View properties for the artist Vincent van Gogh as a "PropertyAssociation".
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_173.png)
EntityValue[
Entity["MoMAArtist", "Vincent van Gogh"], "PropertyAssociation"]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_125.png)
Visualize the distribution of work counts at MoMA for all artists.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_174.png)
Histogram[
Length /@ EntityValue["MoMAArtist", "MoMAPieces"], {"Log", 20}]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_126.png)
Explore the average lifespan of deceased artists by first selecting artists having both birth and death dates defined, then taking the date difference between the two, and finally, computing the average.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_175.png)
deceasedArtists =
Select[EntityList["MoMAArtist"],
AllTrue[# /@ {"BirthDate", "DeathDate"}, DateObjectQ] &];
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_176.png)
Mean[DateDifference[#["BirthDate"], #["DeathDate"], "Year"] & /@
deceasedArtists] // N
![](assets.en/museum-of-modern-art-paintings-and-artists/O_127.png)
Create collages of some randomly selected MoMA pieces from each decade of the twentieth century.
![](assets.en/museum-of-modern-art-paintings-and-artists/O_128.png)