Musée d'art moderne : peintures et artistes
Le musée d'art moderne (Museum of Modern Art, ou MoMA) gère un jeu de données public à l'adresse Internet suivante https://github.com/MuseumofModernArt/collection qui contient des informations détaillées sur ses collections. Ici, vous pouvez utiliser un magasin d'entités personnalisé dérivé de ces données pour étudier les dimensions des peintures du MoMA, ainsi que la longévité de leurs artistes.
Commencez par charger le magasin d'entités préconstruit à partir d'un ResourceObject.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_164.png)
momaStore = ResourceData[
ResourceObject[
Association[
"Name" -> "Museum of Modern Art Holdings and Artists",
"UUID" -> "38f47cc0-667d-4988-8ebe-6c1bef23fdc6",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "Holdings and artists of The Museum of Modern \
Art", "ContentSize" -> Association["EntityStore" -> 0],
"ContentElements" -> {"EntityStore"}]]]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_118.png)
Enregistrez le magasin pour cette session.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_165.png)
PrependTo[$EntityStores, momaStore];
Obtenez une liste de propriétés d'œuvres d'art à partir du magasin d'entités en utilisant le type d'entité "MoMAHolding".
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_166.png)
EntityProperties["MoMAHolding"]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_119.png)
Dressez la liste des valeurs représentatives des propriétés d'une œuvre particulière.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_167.png)
DeleteMissing[
EntityValue[Entity["MoMAHolding", "79802"],
"PropertyAssociation" ]] // Take[#, 15] &
![](assets.en/museum-of-modern-art-paintings-and-artists/O_120.png)
Créez un histogramme des dates d'achèvement de toutes les œuvres du MoMA.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_168.png)
DateHistogram[
DeleteMissing[EntityValue["MoMAHolding", "CompletionDate"]]]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_121.png)
Recensez les types d'œuvres de la collection.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_169.png)
TextGrid[SortBy[
Tally[EntityValue["MoMAHolding",
EntityProperty["MoMAHolding", "Classification"]]], Last] //
Reverse, Dividers -> All,
Background -> {Automatic, {{LightBlue, None}}},
Alignment -> {{Left, Decimal}, Automatic}]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_122.png)
Utilisez des classes d'entités implicitement définies pour retrouver les peintures du MoMA.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_170.png)
paintings =
EntityClass[
"MoMAHolding", {EntityProperty["MoMAHolding", "Classification"] ->
"Painting"}];
Tracez des histogrammes des rapports d'aspect et des surfaces des peintures. Avec la largeur d'échantillonnage par défaut, la distribution des rapports d'aspect semble être trimodale.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_171.png)
Table[Histogram[EntityValue[paintings, prop],
PlotLabel ->
prop], {prop, {EntityProperty["MoMAHolding", "AspectRatio"],
EntityProperty["MoMAHolding", "Area"]}}]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_123.png)
Obtenez maintenant une liste des propriétés associées aux artistes en utilisant le type d'entité "MoMAArtist".
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_172.png)
EntityProperties["MoMAArtist"]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_124.png)
Affichez les propriétés de l'artiste Vincent van Gogh en tant que "PropertyAssociation".
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_173.png)
EntityValue[
Entity["MoMAArtist", "Vincent van Gogh"], "PropertyAssociation"]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_125.png)
Visualisez la distribution du nombre d'œuvres au MoMA pour tous les artistes.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_174.png)
Histogram[
Length /@ EntityValue["MoMAArtist", "MoMAPieces"], {"Log", 20}]
![](assets.en/museum-of-modern-art-paintings-and-artists/O_126.png)
Explorez la durée de vie moyenne des artistes décédés en sélectionnant d'abord les artistes dont les dates de naissance et de décès sont définies, puis en prenant la différence de date entre les deux, et enfin en calculant la moyenne.
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_175.png)
deceasedArtists =
Select[EntityList["MoMAArtist"],
AllTrue[# /@ {"BirthDate", "DeathDate"}, DateObjectQ] &];
![Click for copyable input](assets.en/museum-of-modern-art-paintings-and-artists/In_176.png)
Mean[DateDifference[#["BirthDate"], #["DeathDate"], "Year"] & /@
deceasedArtists] // N
![](assets.en/museum-of-modern-art-paintings-and-artists/O_127.png)
Créez des collages à partir d'œuvres du MoMA sélectionnées au hasard pour chaque décennie du vingtième siècle.
![](assets.en/museum-of-modern-art-paintings-and-artists/O_128.png)