Aspirin herstellen
Aspirin ist eines der am meisten verwendeten Medikamente zur Behandlung von Schmerzen, Fieber und Entzündungen. Es kann aus einer Reaktion aus gleichen Mengen von Salicylsäure und Essigsäureanhydrid hergestellt werden. In diesem Beispiel werden die chemischen Daten aus der Wolfram Knowledgebase gemeinsam mit dem Quantity-Framework, Entitätsgruppen und Entitätsinstanzen verwendet, um die chemische Herstellung von Aspirin zu untersuchen.
Diese EntityGroup repräsentiert eine typische Labor-Charge für eine Herstellung von 100 Millimol Aspirin.
![Click for copyable input](assets.de/prepare-aspirin/In_11.png)
reactants =
EntityGroup[{EntityInstance[Entity["Chemical", "SalicylicAcid"],
Quantity[0.1, "Moles"]],
EntityInstance[Entity["Chemical", "AceticAnhydride"],
Quantity[0.1, "Moles"]]}]
![](assets.de/prepare-aspirin/O_8.png)
Berechnen Sie die Gesamtmasse dieser Charge.
![Click for copyable input](assets.de/prepare-aspirin/In_12.png)
mass = reactants["AbsoluteMass"]
![](assets.de/prepare-aspirin/O_9.png)
Da Essigsäureanhydrid eine Flüssigkeit ist, empfiehlt es sich zu wissen, wie viele Milliliter genau benötigt werden.
![Click for copyable input](assets.de/prepare-aspirin/In_13.png)
UnitConvert[
EntityInstance[Entity["Chemical", "AceticAnhydride"],
Quantity[0.1, "Moles"]]["AbsoluteVolume"], "Milliliter"]
![](assets.de/prepare-aspirin/O_10.png)
Unter der Annahme einer stöchiometrischen, d.h. einer (theoretischen) quantitativen Reaktion, ergibt sich so eine Menge von 100 mmol Aspirin. In der Praxis werden jedoch nur 90% gewonnen.
![Click for copyable input](assets.de/prepare-aspirin/In_14.png)
EntityInstance[Entity["Chemical", "Aspirin"],
0.9*Quantity[0.1, "Moles"]]["AbsoluteMass"]
![](assets.de/prepare-aspirin/O_11.png)
Ermitteln Sie Art und Anzahl der Atome, aus dem das Aspirin-Molekül besteht.
![Click for copyable input](assets.de/prepare-aspirin/In_15.png)
elem = Entity["Chemical", "Aspirin"]["ElementCounts"]
![](assets.de/prepare-aspirin/O_12.png)
Fassen Sie die genaue jeweilige Anzahl dieser Atome in einem gruppierten Entitätsausdruck zusammen.
![Click for copyable input](assets.de/prepare-aspirin/In_16.png)
atomAssemble =
EntityGroup[
MapThread[EntityCopies[#1, #2] &, {Keys[elem], Values[elem]}]]
![](assets.de/prepare-aspirin/O_13.png)
![Click for copyable input](assets.de/prepare-aspirin/In_17.png)
atomicmass = atomAssemble["AtomicMass"]
![](assets.de/prepare-aspirin/O_14.png)
Die Gesamtatommasse dieser Entitätsgruppe stimmt wie erwartet mit der molaren Masse des gesamten Moleküls überein.
![Click for copyable input](assets.de/prepare-aspirin/In_18.png)
molarmass =
Entity["Chemical", "Aspirin"][
EntityProperty["Chemical", "MolarMass"]]
![](assets.de/prepare-aspirin/O_15.png)
![Click for copyable input](assets.de/prepare-aspirin/In_19.png)
Equal @@ QuantityMagnitude /@ {atomicmass, molarmass}
![](assets.de/prepare-aspirin/O_16.png)
Es gibt jedoch zahlreiche isotopische Kombinationen, jede von ihnen mit geringfügig anderer Gesamtmasse.
![Click for copyable input](assets.de/prepare-aspirin/In_20.png)
stableIsotopes = #[EntityProperty["Element", "StableIsotopes"]] & /@
Keys[elem]
![](assets.de/prepare-aspirin/O_17.png)
Diese Gruppe besteht nur aus den Standard-Isotopen (dem sogenannten „Hauption“).
![Click for copyable input](assets.de/prepare-aspirin/In_21.png)
EntityGroup[{EntityCopies[Entity["Isotope", "C12"], 9],
EntityCopies[Entity["Isotope", "H1"], 8],
EntityCopies[Entity["Isotope", "O16"], 4]}]["AtomicMass"]
![](assets.de/prepare-aspirin/O_18.png)
Die Wahrscheinlichkeit des Auftretens eines Moleküls mit solcher Zusammensetzung liegt bei unter 90%. Nichtdestoweniger würde es in einem Massespektrum die prominenteste Molekülspitze verkörpern.
![Click for copyable input](assets.de/prepare-aspirin/In_22.png)
Times @@ MapThread[(QuantityMagnitude[#1[
EntityProperty["Isotope", "IsotopeAbundance"]],
"PureUnities"])^#2 &, {stableIsotopes[[All, 1]], Values[elem]}]
![](assets.de/prepare-aspirin/O_19.png)