Pokémon-Power
Die Wolfram Knowledgebase enthält sowohl Informationen über Ikonen der Popkultur als auch wissenschaftliches Wissen. In diesem Beispiel untersuchen wir unterschiedliche Charakteristika (Angrifs- und Verteidigungspunkte, Gewicht, Farbe) von Pokémon, wir stellen diese gegenüber und visualisieren sie mit dem eingebauten Entitäten-Framework.
Plotten Sie die Verteilungen von Angriffs- und Verteidigungspunkten aller Pokémon.
![Click for copyable input](assets.de/pokemon-power/In_78.png)
PairedHistogram[EntityValue["Pokemon", "Attack"],
EntityValue["Pokemon", "Defense"],
ChartLabels -> {"attack", "defense"},
ChartStyle -> {{LightOrange, LightBlue}, None}]
![](assets.de/pokemon-power/O_59.png)
Erstellen Sie ein Dataset der Angriffs- vs. Verteidigungspunkte der Generation VI-Pokémon.
![Click for copyable input](assets.de/pokemon-power/In_79.png)
stat = EntityValue[Entity[
"Pokemon", {
"Generation" -> Entity[
"PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"},
"Dataset"];
![Click for copyable input](assets.de/pokemon-power/In_80.png)
ListPlot[stat,
PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]],
AxesLabel -> Automatic, LabelingFunction -> None]
![](assets.de/pokemon-power/O_60.png)
Vergleichen und plotten Sie das Durchschnittsgewicht der Pokémon im Laufe der unterschiedlichen Generationen.
![Click for copyable input](assets.de/pokemon-power/In_81.png)
wg = Normal[
GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}],
First -> Last, Mean]]
![](assets.de/pokemon-power/O_61.png)
![Click for copyable input](assets.de/pokemon-power/In_82.png)
BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]],
ChartStyle -> 24]
![](assets.de/pokemon-power/O_62.png)
Verwenden Sie eine implizit definierte Entitätsklasse, um die drei schwersten Pokémon zu eruieren.
![Click for copyable input](assets.de/pokemon-power/In_83.png)
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]
![](assets.de/pokemon-power/O_63.png)
![Click for copyable input](assets.de/pokemon-power/In_84.png)
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]];
EntityValue[%, "Generation"]
![](assets.de/pokemon-power/O_64.png)
Ermitteln Sie die gelben Pokémon der Gewichtsklasse 50 bis 100 kg.
![Click for copyable input](assets.de/pokemon-power/In_85.png)
yellowMidweights = EntityList[
Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{
Quantity[50, "Kilograms"],
Quantity[100, "Kilograms"]}]}]]
![](assets.de/pokemon-power/O_65.png)
Erstellen Sie eine Collage dieser Pokémon-Charaktere, wobei ihre Darstellungsgröße ihrem jeweiligen Gewicht entspricht.
![Click for copyable input](assets.de/pokemon-power/In_86.png)
ImageCollage[
Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}],
Background -> White]
![](assets.de/pokemon-power/O_66.png)
Vergleichen Sie die Farben der Pokémon des Originals (Generation I) und der jüngsten (Generation VI) Gruppen.
![](assets.de/pokemon-power/O_67.png)