Покемоны
Wolfram Knowledgebase содержит информацию о популярных культурных феноменах и явлениях, а также научные знания. В данном примере мы рассмотрим различные физические характеристики (очки за нападения и защиту, вес, цвет) покемонов.
Отобразим на графике распределения атак и точек обороны во всех играх с покемонами.
![Click for copyable input](assets.ru/pokemon-power/In_78.png)
PairedHistogram[EntityValue["Pokemon", "Attack"],
EntityValue["Pokemon", "Defense"],
ChartLabels -> {"attack", "defense"},
ChartStyle -> {{LightOrange, LightBlue}, None}]
![](assets.ru/pokemon-power/O_59.png)
С помощью функции Dataset, cоздадим данные, включающие очки за атаки и оборону для VI поколения покемонов, и отобразим эти данные на графике.
![Click for copyable input](assets.ru/pokemon-power/In_79.png)
stat = EntityValue[Entity[
"Pokemon", {
"Generation" -> Entity[
"PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"},
"Dataset"];
![Click for copyable input](assets.ru/pokemon-power/In_80.png)
ListPlot[stat,
PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]],
AxesLabel -> Automatic, LabelingFunction -> None]
![](assets.ru/pokemon-power/O_60.png)
Сравним и отобразим на графике среднюю массу покемонов разных поколений.
![Click for copyable input](assets.ru/pokemon-power/In_81.png)
wg = Normal[
GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}],
First -> Last, Mean]]
![](assets.ru/pokemon-power/O_61.png)
![Click for copyable input](assets.ru/pokemon-power/In_82.png)
BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]],
ChartStyle -> 24]
![](assets.ru/pokemon-power/O_62.png)
Воспользуемся неявно определенным класс сущностей, чтобы найти три самых тяжелых покемона.
![Click for copyable input](assets.ru/pokemon-power/In_83.png)
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]
![](assets.ru/pokemon-power/O_63.png)
![Click for copyable input](assets.ru/pokemon-power/In_84.png)
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]];
EntityValue[%, "Generation"]
![](assets.ru/pokemon-power/O_64.png)
Воспользуемся неявно определенным классом сущностей, чтобы найти желтых покемонов весом от 50 до 100 кг.
![Click for copyable input](assets.ru/pokemon-power/In_85.png)
yellowMidweights = EntityList[
Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{
Quantity[50, "Kilograms"],
Quantity[100, "Kilograms"]}]}]]
![](assets.ru/pokemon-power/O_65.png)
Создадим коллаж из символов, изображающих покемонов, где размер каждого символа будет соответствовать весу изображенного покемона.
![Click for copyable input](assets.ru/pokemon-power/In_86.png)
ImageCollage[
Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}],
Background -> White]
![](assets.ru/pokemon-power/O_66.png)
Сравним цвета покемонов в первого и новейшего (VI) поколения.
![](assets.ru/pokemon-power/O_67.png)