Определение структуры полихлорированных бифенилов (ПХБ) и публикация через EntityStore
Полихлорированный бифенил (ПХБ) представляет собой органическое соединение с химической формулой . В прошлом ПХБ имели ряд промышленных применений, в том числе, использовались в электрических трансформатарах. В данном примере, мы проиллюстрируем генерацию и хранение формул всех возможных полихлорированных бифенилов (ПХБ) в качестве объектов пользователя.
Данные о химических соединениях ChemicalData уже содержат информацию о ПХБ, часто под названием "дифенил" или "бифенил".
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_113.png)
Entity["Chemical", "Biphenyl"]["ColorStructureDiagram"]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_84.png)
ChemicalData также содержит соединения молекулы ПХБ.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_114.png)
Entity["Chemical", "PCB"][
EntityProperty["Chemical", "ColorStructureDiagram"]]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_85.png)
Общая структура ПХБ включает в себя 10 сторон, обозначенных ниже крестиками. Для того, чтобы получить все возможные моно- дека-хлорированные производные (соединения), хлор-заместители присоединяются к молекуле ПХБ различными способами. Общая структура молекулы в формате "MOL" загружается из заранее созданного объекта файловой системы CloudObject.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_115.png)
molString = CloudGet[CloudObject[
"https://www.wolframcloud.com/objects/user-722de5bb-ef39-4cbd-\
999d-546c888892d6/PCB_scaffold"]][[2]];
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_116.png)
ImportString[molString, "MOL"]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_86.png)
С учетом базовой теории групп мы можем перечислить все структуры ПХБ. Существенным свойством данной структуры будет симметрия, служащая в качестве основы для молекулярных соединений.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_117.png)
biphenylSymmetry =
PermutationGroup[{Cycles[{{6, 10}, {7, 9}}],
Cycles[{{1, 5}, {2, 4}}],
Cycles[{{1, 6}, {2, 7}, {3, 8}, {4, 9}, {5, 10}}]}];
Сформируем цикличный индекс для многочлена на основе теоремы Полна и будем варьировать коэффициенты данного индекса, чтобы получить 210 возможных соединений (включая незамещенную углеводородную структуру, которая не является ПБХ из-за отсутствия хлора).
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_118.png)
ci = Factor[
CycleIndexPolynomial[biphenylSymmetry, Array[Subscript[x, #] &, 4]]]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_87.png)
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_119.png)
Total[CoefficientList[Expand[ci /. Subscript[x, i_] -> (x^i + 1)], x]]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_88.png)
Далее, генерируем 209 наименования полученных соединений в соответствии со стандартами организации IUPAC (Международный союз теоретической и прикладной химии).
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_120.png)
conPos = Flatten[(PositionIndex /@
First /@
GroupOrbits[biphenylSymmetry, Permutations[#],
Permute]) & /@ (LowerTriangularize[
ConstantArray["Cl", {10, 10}]] /. 0 -> "H")] /.
Thread[Range[10] -> {"2", "3", "4", "5", "6", "2'", "3'", "4'",
"5'", "6'"}];
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_121.png)
(names = Flatten[{StringJoin[Riffle[Sort[#["Cl"]], ","]] <>
"-" <> (Length[#["Cl"]] /.
Thread[Range[10] -> {"Chloro", "Dichloro", "Trichloro",
"Tetrachloro", "Pentachloro", "Hexachloro",
"Heptachloro", "Octachloro", "Nonachloro",
"Decachloro"}]) <> "biphenyl"} & /@ conPos] /.
"2,2',3,3',4,4',5,5',6,6'-Decachlorobiphenyl" ->
"Decachlorobiphenyl") // Short
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_89.png)
Аналогичным образом генерируем все возможные структуры соединений.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_122.png)
PCBstruct =
ImportString[
StringReplacePart[molString, #, StringPosition[molString, "X"]],
"MOL"] & /@
Flatten[(First /@
GroupOrbits[biphenylSymmetry, Permutations[#],
Permute]) & /@ (LowerTriangularize[
ConstantArray["Cl", {10, 10}]] /. 0 -> "H"), 1];
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_123.png)
TextGrid[Transpose[{names, PCBstruct}] // Take[#, 2] &,
Dividers -> All]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_90.png)
Для того, чтобы включить в наши данные более подробные свойства полученных соединений, импортируем данныe o ПХБ из уже существующего объектa облачной файловой системы, CloudObject.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_124.png)
imp = CloudGet[CloudObject[
"https://www.wolframcloud.com/objects/user-722de5bb-ef39-4cbd-\
999d-546c888892d6/PCB_congeners_propertylist"]];
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_125.png)
TextGrid[Take[imp, 5], Background -> {Automatic, {LightBlue}},
Dividers -> All]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_91.png)
Объединим импортированные данные с ранее вычисленными структурами и названиями.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_126.png)
TextGrid[(PCBdata =
SortBy[MapThread[
Flatten[{#1,
Pick[imp[[3 ;;]], imp[[3 ;;, 1]], #2]}] &, {PCBstruct,
names}], #[[3]] &]) // Take[#, 2] &, Dividers -> All]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_92.png)
Сохраним информацию о полученных структурах ПХБ в качестве информационного объекта "entity store" (букв. хранилище сущностей).
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_130.png)
store = EntityStore[
"PCB" -> <|
"Label" -> "polychlorinated biphenyl",
"LabelPlural" -> "polychlorinated biphenyls",
"Entities" -> entities,
"Properties" -> properties,
"EntityClasses" -> classes
|>]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_93.png)
Зарегистрируем информацию, подготовленную в данной рабочей сессии.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_131.png)
PrependTo[$EntityStores, store];
Протестируем, доступна ли сохраненная информация для дальнейшего использования.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_132.png)
EntityValue[RandomEntity["PCB"], "PropertyAssociation"]
![](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/O_94.png)
Для того, чтобы все пользовательские информационные объекты были доступны к использованию в дальнейшем (например, для общественных приложений), их необходимо сохранить в качестве объекта облачной системы файлов, CloudObject.
![Click for copyable input](assets.ru/enumerate-pcb-structures-and-share-via-an-entityst/In_133.png)
CloudPut[store, "PCB_entity_store", Permissions -> "Public"]