Анализа и сравнение продуктов питания "Superfoods"
В данном примере речь пойдет о продуктах с очень высоким содержанием одного или нескольких питательных веществ. Мы рассмотрим набор таких "супер-продуктов" и противопоставим их более "типичным" продуктам. Для этого, мы воспользуемся данными о продуктах питания из базы знаний Wolfram Knowledgebase. Мы определим отличительные характеристики, подходящие для определения пищевых продуктов, достойных эпитета "супер".
Для начала, определим список супер-продуктов с высоким содержанием питательных веществ.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_297.png)
superfoodsRawData = {{"greek yogurt", {"TotalProtein"}}, {"quinoa", \
{"TotalProtein"}}, {"blueberries", {"TotalFiber",
"VitaminC"}}, {"kale", {"TotalFiber", "Calcium",
"Iron"}}, {"chia", {"Magnesium", "Iron", "Calcium",
"Potassium"}}, {"oatmeal", {"TotalFiber"}}, {"broccoli", \
{"TotalFiber", "VitaminC",
"TotalFolate"}}, {"strawberries", {"VitaminC"}}, {"salmon", \
{"TotalProtein"}}, {"watermelon", {"TotalSugar", "VitaminA",
"VitaminC", "TotalCalories"}}, {"lima beans", {"TotalFiber"}},
{"edamame", {"TotalFiber"}}, {"spinach", {"Calcium",
"VitaminK"}}, {"pistachios", {"TotalProtein", "TotalFiber",
"Potassium"}}, {"eggs", {"TotalProtein"}}, {"almonds", \
{"TotalFiber", "Potassium", "Calcium", "VitaminE", "Magnesium",
"Iron"}}, {"pumpkin", {"BetaCarotene"}}, {"apples", \
{"TotalFiber", "TotalCalories"}}, {"lentils", {"TotalProtein",
"Iron"}}};
Преобразуем эту информацию в набор данных, Dataset, для упрощения вычислений.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_298.png)
superfoodsDatset =
Dataset[<|"Food" -> #1, "Nutrients" -> #2|> & @@@ superfoodsRawData]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_199.png)
Воспользуемся функцией Interpreter языковых объектов Wolfram Language для супер-продуктов.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_299.png)
superfoodsDatset1 =
superfoodsDatset[All,
KeySort[Prepend[#, <|
"FoodEntity" -> Interpreter["Food"][#Food]|>]] &];
Перечислим питательные вещества, содержащиеся в этих продуктах.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_300.png)
Union @@ Normal[superfoodsDatset1[[All, "Nutrients"]]]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_200.png)
Генерируем правила для преобразования данных питательных веществ в их соответствующие свойства.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_301.png)
superfoodsDatset2 =
superfoodsDatset1 /.
AssociationMap[
EntityProperty["Food", "Relative" <> # <> "Content"] &,
Union @@ Normal[superfoodsDatset1[[All, "Nutrients"]]]]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_201.png)
Определим наиболее распространенные питательные вещества в нашем наборе данных, Dataset.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_302.png)
mostCommonProperties =
superfoodsDatset2[Counts[Flatten[#]] &, "Nutrients"][TakeLargest[5]]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_202.png)
Определим суперпродукты с высоким содержанием клетчатки и сравним их с почти 9000 других пищевых продуктов. Визуализируем эти данные с помощью сглаженной гистограммы, на которой серая кривая показывает функцию плотности вероятности содержания волокон клетчатки в данных продуктах питания.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_303.png)
fiberDataset =
superfoodsDatset2[
Select[ContainsAny[#Nutrients, {EntityProperty["Food",
"RelativeTotalFiberContent"]}] &], KeyDrop["Nutrients"]];
![](assets.ru/analyze-visualize-and-compare-superfoods/O_203.png)
Проведем похожий анализ для супер-продуктов, богатых белком.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_310.png)
proteinDataset =
superfoodsDatset2[
Select[ContainsAny[#Nutrients, {EntityProperty["Food",
"RelativeTotalProteinContent"]}] &], KeyDrop["Nutrients"]];
![](assets.ru/analyze-visualize-and-compare-superfoods/O_204.png)
Создадим визуальные обозначения для супер-продуктов. Для этого, подберем подходящие изображения.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_318.png)
GraphicsGrid[
Partition[
ims = EntityValue[
Cases[superfoodsDatset2[All, "FoodEntity"] // Normal,
Entity["FoodType", _], Infinity], "Image"], UpTo[5]]]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_205.png)
В качестве схемы изображения, воспользуемся эмблемой супермена.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_319.png)
Entity["Lamina", "SupermanInsigniaLamina"]["Image"] // ImageCrop
![](assets.ru/analyze-visualize-and-compare-superfoods/O_206.png)
Воспользуемся простым способом обработки изображений для преобразования изображения эмблемы супермена в фоновое изображение.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_320.png)
background =
ColorNegate[
Binarize[Entity["Lamina", "SupermanInsigniaLamina"]["Image"], .99]]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_207.png)
Создадим облако, состоящее из изображений супер-продуктов.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_321.png)
wc = WordCloud[(RandomReal[{0.6, 1.2}] -> #) & /@ ims, background]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_208.png)
Совместим облако и подготовленных ранее фон.
![Click for copyable input](assets.ru/analyze-visualize-and-compare-superfoods/In_322.png)
ImageMultiply[{ColorReplace[background, Black -> LightGray], wc}]
![](assets.ru/analyze-visualize-and-compare-superfoods/O_209.png)