Visualize the Wolfram Language
The structure of the Wolfram Language and its relationships with the Wolfram Knowledgebase can be visualized in a number of interesting ways. In this example, you can make a word cloud encapsulating aspects of this relationship, computationally explore and assemble example outputs from the documentation, and visualize the places and times associated with people whose names appear as part of Wolfram Language symbols.
Create a word cloud of terms appearing in the WolframLanguageData documentation.
![Click for copyable input](assets.en/visualize-the-wolfram-language/In_263.png)
WordCloud[
DeleteStopwords[
Flatten[TextWords[
WolframLanguageData["WolframLanguageData", "TextStrings"]]]]]
![](assets.en/visualize-the-wolfram-language/O_179.png)
Create a collage of basic documentation example outputs for Plot.
![Click for copyable input](assets.en/visualize-the-wolfram-language/In_264.png)
ImageCollage[
Cases[WolframLanguageData["Plot", "DocumentationBasicExamples"],
c : Cell[_, "Output", ___] :> Rasterize[RawBoxes[c]], \[Infinity]],
ImagePadding -> 10, Background -> Transparent]
![](assets.en/visualize-the-wolfram-language/O_180.png)
Create a collage of all documentation example output graphics for Plot.
![](assets.en/visualize-the-wolfram-language/O_181.png)
View images of people associated with the LaplacianGaussianFilter symbol in the Wolfram Language.
![Click for copyable input](assets.en/visualize-the-wolfram-language/In_267.png)
ImageAssemble[
PersonData[
WolframLanguageData["LaplacianGaussianFilter", "EponymousPeople"],
"Image"]]
![](assets.en/visualize-the-wolfram-language/O_182.png)
Extract people after whom Wolfram Language symbols are named.
![Click for copyable input](assets.en/visualize-the-wolfram-language/In_268.png)
people = DeleteCases[
Union[Flatten[
WolframLanguageData[All, "EponymousPeople"]]], _Missing];
Obtain information on their birthplaces.
![Click for copyable input](assets.en/visualize-the-wolfram-language/In_269.png)
placedata =
DeleteCases[
PersonData[
people, {"Image", "BirthPlace", "Name"}], {_, _Missing, _}];
View these locations and their associated people on a map of the world.
![](assets.en/visualize-the-wolfram-language/O_183.png)
Extract birth and death dates for people after whom Wolfram Language symbols are named.
![Click for copyable input](assets.en/visualize-the-wolfram-language/In_271.png)
timedata =
Block[{EntityFramework`$EntityValueBatchSize = 300},
DeleteCases[
PersonData[
people, {"BirthDate", "DeathDate", "Name",
"Image"}], {_Missing, __}]];
Make a timeline plot.
![](assets.en/visualize-the-wolfram-language/O_184.png)