Misiones espaciales tripuladas
MannedSpaceMissionData proporciona información histórica y actualizada acerca de la exploración humana en el espacio.
![Click for copyable input](assets.es/manned-space-missions/In_127.png)
missions = MannedSpaceMissionData[];
Usted puede crear un EventSeries con base en la fecha de lanzamiento de las misiones con valores de vector narrando la misión como entidad y la duración de cada misión.
![Click for copyable input](assets.es/manned-space-missions/In_128.png)
data = DeleteMissing[
MannedSpaceMissionData[
missions, {"LaunchDate", "Entity", "MissionDuration"}], 1, 2];
![Click for copyable input](assets.es/manned-space-missions/In_129.png)
es = EventSeries[data[[All, {2, 3}]], {data[[All, 1]]}]
![](assets.es/manned-space-missions/O_73.png)
El gráfico TimelinePlot de las marcas de tiempo muestra el intervalo casi continuo de las misiones espaciales tripuladas desde 1961.
![Click for copyable input](assets.es/manned-space-missions/In_130.png)
TimelinePlot[es["Dates"]]
![](assets.es/manned-space-missions/O_74.png)
Para analizar las duraciones de las misiones, extraiga el segundo componente de la serie de eventos original y convierta los valores a horas.
![Click for copyable input](assets.es/manned-space-missions/In_131.png)
durations = UnitConvert[es["PathComponent", 2], "Hours"]
![](assets.es/manned-space-missions/O_75.png)
Las misiones más cortas son más comunes.
![Click for copyable input](assets.es/manned-space-missions/In_132.png)
Histogram[durations, Quantity[{0, 6000, 500}, "Hours"],
AxesLabel -> Automatic]
![](assets.es/manned-space-missions/O_76.png)
![Click for copyable input](assets.es/manned-space-missions/In_134.png)
DateListPlot[{durations, line1, line2}, opts]
![](assets.es/manned-space-missions/O_77.png)
Calcule algunas estadísticas descriptivas de las duraciones de las misiones. Note que la media y la mediana están alejadas una de otra, indicando una larga cola de distribución.
![Click for copyable input](assets.es/manned-space-missions/In_135.png)
stats = {Min, Max, Mean, Median};
convert :=
UnitConvert[N[#], MixedUnit[{"Months", "Days", "Hours", "Minutes"}]]
&
![Click for copyable input](assets.es/manned-space-missions/In_136.png)
TableForm[Map[convert[#[durations]] &, stats],
TableHeadings -> {stats}]
![](assets.es/manned-space-missions/O_78.png)
El tiempo total en que un humano ha estado en el espacio.
![Click for copyable input](assets.es/manned-space-missions/In_137.png)
UnitConvert[Total[durations],
MixedUnit[{"Years", "Months", "Days", "Hours", "Minutes",
"Seconds"}]]
![](assets.es/manned-space-missions/O_79.png)