Пилотируемые космические миссии
Данные о пилотируемых космических миссиях, MannedSpaceMissionData, предоставляют историческую и актуальную информацию об освоении космического пространства человеком.
![Click for copyable input](assets.ru/manned-space-missions/In_128.png)
missions = MannedSpaceMissionData[];
Зададим данные для ряда событий, EventSeries, на основе даты запуска миссий с векторными значениями, оражающими цели и продолжительность каждой миссии.
![Click for copyable input](assets.ru/manned-space-missions/In_129.png)
data = DeleteMissing[
MannedSpaceMissionData[
missions, {"LaunchDate", "Entity", "MissionDuration"}], 1, 2];
![Click for copyable input](assets.ru/manned-space-missions/In_130.png)
es = EventSeries[data[[All, {2, 3}]], {data[[All, 1]]}]
![](assets.ru/manned-space-missions/O_73.png)
Временная шкала TimelinePlot показывает почти непрерывный диапазон пилотируемых миссий, осуществлённых с 1961 года.
![Click for copyable input](assets.ru/manned-space-missions/In_131.png)
TimelinePlot[es["Dates"]]
![](assets.ru/manned-space-missions/O_74.png)
Для анализа продолжительности миссий, извлечем второй компонент исходного ряда событий и преобразуем значения в часы.
![Click for copyable input](assets.ru/manned-space-missions/In_132.png)
durations = UnitConvert[es["PathComponent", 2], "Hours"]
![](assets.ru/manned-space-missions/O_75.png)
Короткие миссии являются наиболее распространенными.
![Click for copyable input](assets.ru/manned-space-missions/In_133.png)
Histogram[durations, Quantity[{0, 6000, 500}, "Hours"],
AxesLabel -> Automatic]
![](assets.ru/manned-space-missions/O_76.png)
![Click for copyable input](assets.ru/manned-space-missions/In_135.png)
DateListPlot[{durations, line1, line2}, opts]
![](assets.ru/manned-space-missions/O_77.png)
Рассчитаем описательную статистику длительности космических миссий. Обратим внимание на тот факт, что среднее значение и среднее медианы равнозначно удалены друг от друга, что указывает на длинный хвост распределения.
![Click for copyable input](assets.ru/manned-space-missions/In_136.png)
stats = {Min, Max, Mean, Median};
convert :=
UnitConvert[N[#], MixedUnit[{"Months", "Days", "Hours", "Minutes"}]]
&
![Click for copyable input](assets.ru/manned-space-missions/In_137.png)
TableForm[Map[convert[#[durations]] &, stats],
TableHeadings -> {stats}]
![](assets.ru/manned-space-missions/O_78.png)
Общее время пребывания человека в космосе.
![Click for copyable input](assets.ru/manned-space-missions/In_138.png)
UnitConvert[Total[durations],
MixedUnit[{"Years", "Months", "Days", "Hours", "Minutes",
"Seconds"}]]
![](assets.ru/manned-space-missions/O_79.png)