Visualisez les modèles saisonniers
Comparez les précipitations saisonnières dans la région centrale et sud-ouest.
WeatherData fournit des précipitations agrégées en cm.
In[1]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_63.png)
start = {1999, 1, 1};
end = {2015, 12, 31};
In[2]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_64.png)
getData[place_] :=
WeatherData[place, "TotalPrecipitation", {start, end, "Month"}]
Créez une TimeSeries des précipitations pour Champaign, IL, et Phoenix, AZ. Spécifiez MissingDataMethod pour utiliser l'interpolation afin de compléter les données manquantes.
In[3]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_65.png)
makeTS[place_] :=
TimeSeries[getData[place], MissingDataMethod -> "Interpolation"]
In[4]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_66.png)
tsIL = makeTS[
Entity["City", {"Champaign", "Illinois", "UnitedStates"}]]
Out[4]=
![](assets.fr/visualize-seasonal-patterns/O_35.png)
In[5]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_67.png)
tsAZ = makeTS[Entity["City", {"Phoenix", "Arizona", "UnitedStates"}]]
Out[5]=
![](assets.fr/visualize-seasonal-patterns/O_36.png)
Créez WeightedData avec les quantités de précipitations comme poids et tracez DateHistogram en calculant la moyenne des données sur le nombre total d'années.
In[6]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_68.png)
dataIL = WeightedData[tsIL["Dates"], tsIL["Values"]];
dataAZ = WeightedData[tsAZ["Dates"], tsAZ["Values"]];
In[7]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_69.png)
totalyears = (end[[1]] - start[[1]] + 1);
In[8]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_70.png)
avg := Function[{x, y}, y/totalyears]
In[9]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_71.png)
makeHistogram[data_, lab_] :=
DateHistogram[data, "Month", avg, DateReduction -> "Year",
PlotRange -> {All, {-1, 9}}, AxesLabel -> "cm", PlotLabel -> lab]
In[10]:=
![Click for copyable input](assets.fr/visualize-seasonal-patterns/In_72.png)
{makeHistogram[dataIL, "IL"], makeHistogram[dataAZ, "AZ"]}
Out[10]=
![](assets.fr/visualize-seasonal-patterns/O_37.png)