Converta para o calendário maia
Identifique a época (ou data de início) para o calendário maia de contagem longa como uma data juliana.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_59.png)
epoch = JulianDate["Modified",
DateObject[{-3114, 8, 11}, TimeZone -> 0]];
Crie uma função para converter de unidades do calendário maia de contagem longa para uma data juliana.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_60.png)
JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] :=
epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin
FromJulianDate pode ser usada para testar um exemplo de input.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_61.png)
example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]
![](assets.pt-br/convert-to-the-mayan-calendar/O_54.png)
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_62.png)
FromJulianDate["Modified", example, TimeZone -> 0]
![](assets.pt-br/convert-to-the-mayan-calendar/O_55.png)
Crie uma função para converter uma data juliana em unidades de calendário maia de contagem longa.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_63.png)
GregorianFromMayanLongCount[date_] := DateValue[
FromJulianDate["Modified",
JulianFromMayanLongCount[date],
TimeZone -> 0],
"Day",
DateObject]
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_64.png)
GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]
![](assets.pt-br/convert-to-the-mayan-calendar/O_56.png)
Crie uma função para converter uma data juliana em unidades de calendário maia de contagem longa.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_65.png)
JulianToMayanLongCount[date_] := NumberDecompose[
Floor[date - epoch],
{144000, 7200, 360, 20, 1}
]
JulianDate pode ser usada para interpretar qualquer input de data em data juliana, que depois é inserida em JulianToMayanLongCount.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_66.png)
DateToMayanLongCount[date_] := Block[{$TimeZone = 0},
JulianToMayanLongCount[JulianDate["Modified", date]]
]
Esta função irá agora aceitar qualquer input de data e retornará o lista correspondente de datas do calendário maia de contagem longa.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_67.png)
DateToMayanLongCount["May 4th, 2015"]
![](assets.pt-br/convert-to-the-mayan-calendar/O_57.png)
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_68.png)
DateToMayanLongCount[AbsoluteTime[]]
![](assets.pt-br/convert-to-the-mayan-calendar/O_58.png)
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_69.png)
DateToMayanLongCount[Today]
![](assets.pt-br/convert-to-the-mayan-calendar/O_59.png)
Estas duas funções podem ser usadas para converter de e para o calendário maia de contagem longa.
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_70.png)
DateToMayanLongCount[{1900, 1, 1}]
![](assets.pt-br/convert-to-the-mayan-calendar/O_60.png)
![Click for copyable input](assets.pt-br/convert-to-the-mayan-calendar/In_71.png)
DateToMayanLongCount[{1900, 1, 1}];
GregorianFromMayanLongCount[%]
![](assets.pt-br/convert-to-the-mayan-calendar/O_61.png)