Convert to the Mayan Calendar
Identify the epoch (or start date) for the Mayan Long Count calendar as a Julian date.
In[1]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_59.png)
epoch = JulianDate["Modified",
DateObject[{-3114, 8, 11}, TimeZone -> 0]];
Create a function to convert from Mayan Long Count calendar units to a Julian date.
In[2]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_60.png)
JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] :=
epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin
FromJulianDate can be used to test an example input.
In[3]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_61.png)
example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]
Out[3]=
![](assets.en/convert-to-the-mayan-calendar/O_54.png)
In[4]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_62.png)
FromJulianDate["Modified", example, TimeZone -> 0]
Out[4]=
![](assets.en/convert-to-the-mayan-calendar/O_55.png)
Create a function to convert directly from Mayan Long Count to Gregorian date objects.
In[5]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_63.png)
GregorianFromMayanLongCount[date_] := DateValue[
FromJulianDate["Modified",
JulianFromMayanLongCount[date],
TimeZone -> 0],
"Day",
DateObject]
In[6]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_64.png)
GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]
Out[6]=
![](assets.en/convert-to-the-mayan-calendar/O_56.png)
Create a function to convert from a Julian date to Mayan Long Count calendar units.
In[7]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_65.png)
JulianToMayanLongCount[date_] := NumberDecompose[
Floor[date - epoch],
{144000, 7200, 360, 20, 1}
]
JulianDate can be used to interpret any date input into a Julian date, which is then fed into JulianToMayanLongCount.
In[8]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_66.png)
DateToMayanLongCount[date_] := Block[{$TimeZone = 0},
JulianToMayanLongCount[JulianDate["Modified", date]]
]
This function will now accept any input date and will return the corresponding Mayan Long Count calendar date list.
In[9]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_67.png)
DateToMayanLongCount["May 4th, 2015"]
Out[9]=
![](assets.en/convert-to-the-mayan-calendar/O_57.png)
In[10]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_68.png)
DateToMayanLongCount[AbsoluteTime[]]
Out[10]=
![](assets.en/convert-to-the-mayan-calendar/O_58.png)
In[11]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_69.png)
DateToMayanLongCount[Today]
Out[11]=
![](assets.en/convert-to-the-mayan-calendar/O_59.png)
These two functions can be used to convert to and from the Long Count Mayan calendar.
In[12]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_70.png)
DateToMayanLongCount[{1900, 1, 1}]
Out[12]=
![](assets.en/convert-to-the-mayan-calendar/O_60.png)
In[13]:=
![Click for copyable input](assets.en/convert-to-the-mayan-calendar/In_71.png)
DateToMayanLongCount[{1900, 1, 1}];
GregorianFromMayanLongCount[%]
Out[13]=
![](assets.en/convert-to-the-mayan-calendar/O_61.png)