This gives the coordinates of eight points with 45° spacing around a circle (type deg to get the degree symbol (°)):

In[1]:=1

✖

Table[{Sin[t 45 \[Degree]], Cos[t 45 \[Degree]]}, {t, 8}]

Out[1]=1

This draws the points:

In[2]:=2

✖

Graphics[Point[ Table[{Sin[t 45 \[Degree]], Cos[t 45 \[Degree]]}, {t, 8}]], Axes -> True]

Out[2]=2

Make the angle smaller and the number of points larger to get a tighter circle of points (a lot of the points overlap):

In[3]:=3

✖

Graphics[Point[ Table[{Sin[t 5 \[Degree]], Cos[t 5 \[Degree]]}, {t, 400}]], Axes -> True]

Out[3]=3

Multiply by the square root of t to make the points spiral out from the center:

In[4]:=4

✖

Graphics[Point[ Table[Sqrt[t] {Sin[t 5 \[Degree]], Cos[t 5 \[Degree]]}, {t, 400}]], Axes -> True]

Out[4]=4

Out[1]=1

Plant structures like the daisy flower above are often arranged in spirals whose angle is the “golden angle”:

In[1]:=1

✖

ga = 360./GoldenRatio^2

Out[1]=1

When you draw spirals with the golden angle, the points pack together evenly throughout:

In[2]:=2

✖

Graphics[Point[ Table[Sqrt[t] {Sin[t ga \[Degree]], Cos[t ga \[Degree]]}, {t, 400}]]]

Out[2]=2

Make the points larger with PointSize (put multiple graphics elements in a list, indicated by curly braces):

In[1]:=1

✖

ga = 360./GoldenRatio^2; Graphics[{PointSize[.03], Point[Table[ Sqrt[t] {Sin[t ga \[Degree]], Cos[t ga \[Degree]]}, {t, 400}]]}]

Out[1]=1

Make the points red:

In[2]:=2

✖

ga = 360./GoldenRatio^2; Graphics[{PointSize[.03], Red, Point[Table[ Sqrt[t] {Sin[t ga \[Degree]], Cos[t ga \[Degree]]}, {t, 400}]]}]

Out[2]=2

The arrangement you get with the golden angle is very sensitive to changes in the angle. Changing the angle by a tiny amount from the golden angle—just one tenth of a degree here—destroys the nice packing:

In[1]:=1

✖

ga = 360./GoldenRatio^2; Graphics[{PointSize[.03], Red, Point[Table[ Sqrt[t] {Sin[t (ga + 0.1) \[Degree]], Cos[t (ga + 0.1) \[Degree]]}, {t, 400}]]}]

Out[1]=1

Make an interactive interface to explore angles using Manipulate.

Wrap the Graphics expression with Manipulate, replace the fixed angle ga with the variable a, and specify that a ranges from 0 to 360, with an initial value of ga. The option Appearance“Labeled” puts the angle value next to the slider, so you can see how it changes as you drag the slider:

In[2]:=2

✖

ga = 360./GoldenRatio^2; Manipulate[ Graphics[{Red, PointSize[.03], Point[Table[ Sqrt[t] {Sin[t a \[Degree]], Cos[t a \[Degree]]}, {t, 400}]]}], {{a, ga, "angle"}, 0, 360, Appearance -> "Labeled"} ]

Out[2]=2

Replace the fixed point size .03 with the variable s and the fixed number of points 400 with n:

In[1]:=1

✖

ga = 360./GoldenRatio^2; Manipulate[ Graphics[{Red, PointSize[s], Point[Table[ Sqrt[t] {Sin[t a \[Degree]], Cos[t a \[Degree]]}, {t, n}]]}], {{a, ga, "angle"}, 0, 360, Appearance -> "Labeled"}, {{n, 400, "number of points"}, 1, 1000}, {{s, .03, "size of points"}, 0, .05} ]

Out[1]=1