This draws a default rectangle, which is a horizontal square:

In[1]:=1

✖

Graphics[Rectangle[]]

Out[1]=1

This draws the square rotated:

In[2]:=2

✖

Graphics[Rotate[Rectangle[], 30 Degree]]

Out[2]=2

You can make anything interactive in the Wolfram Language with Manipulate—for example, this code:

In[1]:=1

✖

Graphics[Rotate[Rectangle[], 30 Degree]]

First replace the numeric angle value with a variable named angle:

In[2]:=2

✖

Graphics[Rotate[Rectangle[], angle Degree]]

Then wrap the expression with Manipulate and specify the range of the variable. Manipulate automatically constructs an interface with a slider that controls the value of the angle:

In[3]:=3

✖

Manipulate[ Graphics[Rotate[Rectangle[], angle Degree]], {angle, 0, 360} ]

Out[3]=3

Table makes lists of elements, one for each value of a variable in a specified range. For example, this makes a list of even numbers:

In[1]:=1

✖

Table[2 r, {r, 0, 10}]

Out[1]=1

This uses Table to make a stack of rectangles, each one rotated 5 degrees more than the one below it. It doesn’t look like a stack of rectangles because you can’t see their edges:

In[2]:=2

✖

Graphics[{Table[Rotate[Rectangle[], r 5 Degree], {r, 0, 10}]}]

Out[2]=2

Make the edges white so you can see the individual rectangles in the stack:

In[3]:=3

✖

Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], r 5 Degree], {r, 0, 10}]}]

Out[3]=3

This draws a stack of rectangles:

In[1]:=1

✖

Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], r 5 Degree], {r, 0, 10}]}]

Out[1]=1

Make that expression interactive with Manipulate. Replace the numeric angle value with a variable named angle:

In[2]:=2

✖

Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], r angle Degree], {r, 0, 10}]}]

Then wrap the expression with Manipulate and specify the range of the angle variable:

In[3]:=3

✖

Manipulate[ Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], r angle Degree], {r, 0, 10}]}], {angle, 0, 360} ]

Out[3]=3

The number of squares in this expression is determined by the value 10:

In[1]:=1

✖

Manipulate[ Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], angle r Degree], {r, 0, 10}]}], {angle, 0, 45} ]

Out[1]=1

Replace 10 by the variable n, and specify that n goes from 1 to 100 in steps of 1:

In[2]:=2

✖

Manipulate[ Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], angle r Degree], {r, 0, n}]}], {angle, 0, 45}, {n, 1, 100, 1} ]

Out[2]=2

This draws a stack of squares rotated in 5-degree increments:

In[1]:=1

✖

Graphics[{EdgeForm[White], Table[Rotate[Rectangle[], 5 r Degree], {r, 0, 10}]}]

Out[1]=1

This uses Scale to scale down the squares as they rotate. The scale factor is 1-r/10, which goes from 1 to 0 as r goes from 0 to 10. The effect is to scale the squares from full-sized down to nothing:

In[2]:=2

✖

Graphics[{EdgeForm[White], Table[Scale[Rotate[Rectangle[], 5 r Degree], 1 - r/10], {r, 0, 10}]}]

Out[2]=2

Add scaling so that the rectangles get smaller as they rotate. Now you have a complete interface for exploring spiral designs:

In[1]:=1

✖

Manipulate[ Graphics[{EdgeForm[White], Table[Scale[Rotate[Rectangle[], angle r Degree], 1 - r/n], {r, 0, n}]}], {angle, 0, 45}, {n, 1, 100} ]

Out[1]=1

Deploy the Manipulate to the Wolfram Cloud, where anyone with a browser can use it:

In[1]:=1

✖

CloudDeploy[ Manipulate[ Graphics[{EdgeForm[White], Table[Scale[Rotate[Rectangle[], angle r Degree], 1 - r/n], {r, 0, n}]}], {angle, 0, 45}, {n, 1, 100} ], Permissions -> "Public" ]

Out[1]=1

Click the link in the output to visit the site.

Tell the world about your creation by sharing the link via email, tweet or other message.