Yoga para saúde e conhecimento
A Wolfram Knowledgebase inclui um conjunto de dados selecionados de posições de yoga. Como resultado, as relações entre as posições, seus níveis de dificuldade, os músculos que envolvem, suas durações, e muitas outras características podem ser exploradas e estudadas de maneira programática simples, poderosa e precisa.
Visualize as relações entre posições de yoga com base nas relações de "PreparatoryPoses", começando pela posição escorpião.
poseGraph =
NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &,
Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name",
VertexLabelStyle -> LightGray]
Mostre imagens esquemáticas de diversas poses.
With[{v = Take[VertexList[poseGraph], 5]},
schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}]
] // Column
Faça um gráfico de posições agrupadas por "comunidades" que compartilham uma relação.
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e,
VertexLabels -> Placed["Name", Tooltip]]
Conte o número de músculos contraídos na série de posições em uma sequência primária de Ashtanga yoga e faça um gráfico do número de músculos envolvidos.
Ache os músculos que são alongados na série Saudação ao Sol A e visualize o músculo que é alongado com mais frequência.
muscles = (SortBy[
Tally[DeleteMissing[
Flatten[EntityValue[
Cases[Entity["YogaSequence", "SunSalutationA"][
"PrimaryPoseSequence"], _Entity, Infinity],
"StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
Visualize o músculo que é alongado com mais frequência.
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
Use uma classe de entidade definida implicitamente para encontrar e visualizar posições de ioga para iniciantes e de média intensidade que alonguem a perna e fortaleçam o abdomem.
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]]
Veja imagens esquemáticas dessas posições como uma associação de entidades.
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]];
EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
Mostre as posições avançadas de yoga que fortalecem o músculo iliopsoas e alongam os isquiossurais.
EntityValue[
Entity["YogaPose", {"ExperienceLevel" -> "Advanced",
"PrimaryContractedMuscles" ->
Entity["AnatomicalStructure", "Iliopsoas"],
"StretchedMuscles" ->
Entity["AnatomicalStructure",
"SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
Encontre sequências de ioga com durações entre 30 e 60 minutos.
EntityList@
Entity["YogaSequence", {"EstimatedDuration" ->
Quantity[ Interval[{30, 60}], "Minutes"]}]