スペクトルの特徴に基づいた音声のクラスタリング
スペクトルの特徴を使って,音声オブジェクトのリスト内のクラスタを見付ける.
In[1]:=
![Click for copyable input](assets.ja/audio-clustering-based-on-spectral-features/In_65.png)
a = ExampleData[{"Audio", "Drums"}, "Audio"]
過渡信号が発声するところで録音音声を分割する.
In[2]:=
![Click for copyable input](assets.ja/audio-clustering-based-on-spectral-features/In_66.png)
samples =
Select[AudioSplit[a,
FindPeaks[AudioLocalMeasurements[a, "Novelty"]]["Times"]],
Duration@# > Quantity[50, "ms"] &];
samples = Audio[#, Appearance -> "Minimal"] & /@ samples
Out[2]=
![](assets.ja/audio-clustering-based-on-spectral-features/O_30.png)
スペクトル中心およびスペクトル拡散によって定義された位置での結果のサンプルをプロットする.
In[3]:=
![Click for copyable input](assets.ja/audio-clustering-based-on-spectral-features/In_67.png)
ListPlot[Partition[
AudioMeasurements[#, {"SpectralCentroid", "SpectralSpread"},
"List"] & /@ samples, 1],
PlotMarkers -> (Audio[#, Appearance -> "Minimal"] & /@ samples),
AxesLabel -> {Style["Centroid", Italic], Style["Spread", Italic]},
ImageSize -> Medium]
Out[3]=
![](assets.ja/audio-clustering-based-on-spectral-features/O_31.png)
"SpectralCentroid"および"SpectralSpread"の測定値を使って,類似のサウンドを求める.
In[4]:=
![Click for copyable input](assets.ja/audio-clustering-based-on-spectral-features/In_68.png)
FindClusters[
AudioMeasurements[#, {"SpectralCentroid", "SpectralSpread"},
"List"] & /@ samples -> samples]
Out[4]=
![](assets.ja/audio-clustering-based-on-spectral-features/O_32.png)