Тон Шепарда: слуховая иллюзия
Создадим слуховую иллюзию.
In[1]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_103.png)
range = 12;
duration = 10;
lfoFreq = .05;
basePitch = 30;
numOsc = 8;
midiToFreq[m_] := 2^((m - 69)/12)*440.
Сформируем пандусы для контроля частоты и амплитуды осцилляторов.
In[2]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_104.png)
phasors =
Table[AudioGenerator[{"Sawtooth", lfoFreq, 2. Pi/numOsc (i - 1.)},
duration, SampleRate -> 500]/2. + .5, {i, numOsc}];
AudioPlot[phasors, PlotLayout -> "Overlaid", PlotRange -> All]
Out[2]=
![](assets.ru/shepards-tone-an-auditory-illusion/O_46.png)
Зададим частотности, которые будут управлять осцилляторами. Частотности будут отличаться с точностью в одну октаву и будут увеличиваться экспоненциально так, что основной тон будет возрастать алинейно.
In[3]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_105.png)
freqs = Table[
midiToFreq[(phasors[[i]])*12*numOsc + basePitch], {i, numOsc}];
AudioPlot[freqs, PlotLayout -> "Overlaid", PlotRange -> All]
Out[3]=
![](assets.ru/shepards-tone-an-auditory-illusion/O_47.png)
Зададим амплитуды, которые будут управлять осцилляторами. Амплитуды будут равны 0, когда частотности снизятся до минимального значения.
In[4]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_106.png)
amps = Cos[#*Pi - Pi/2.] & /@ phasors;
AudioPlot[amps, PlotLayout -> "Overlaid", PlotRange -> All]
Out[4]=
![](assets.ru/shepards-tone-an-auditory-illusion/O_48.png)
Покажeм соотношение между частотностью и амплитудой одного осциллятора.
In[5]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_107.png)
AudioPlot[AudioNormalize /@ {freqs[[2]], amps[[2]]}, PlotRange -> All]
Out[5]=
![](assets.ru/shepards-tone-an-auditory-illusion/O_49.png)
Объединим осцилляторы в единый банк с использованием созданных значений частотностей и амплитуд.
In[6]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_108.png)
res = Mean[
Table[amps[[i]] AudioGenerator[{"Sin", freqs[[i]]}], {i, numOsc}]]
In[7]:=
![Click for copyable input](assets.ru/shepards-tone-an-auditory-illusion/In_109.png)
Spectrogram[res, 8192, 4096, HannWindow,
PlotRange -> {All, {0, 10000}}, ImageSize -> Medium]
Out[7]=
![](assets.ru/shepards-tone-an-auditory-illusion/O_50.png)