Минимальная и максимальная температура
При помощи новой функции MinMax становится возможным одновременное получение минимального и максимального значения в списке температурных значений.
Далее представлены сгенерированные данные о температуре в городе Якутск за 15-летний период.
In[1]:=
![Click for copyable input](assets.ru/temperature-minmax/In_1.png)
data = AirTemperatureData[
Entity["City", {"Yakutsk", "Yakutia", "Russia"}], {{2001,
01}, {2015, 12}, "Month"}]
Out[1]=
![](assets.ru/temperature-minmax/O_1.png)
Полученные временные ряды могут быть визуализированы при помощи DateListPlot.
In[2]:=
![Click for copyable input](assets.ru/temperature-minmax/In_2.png)
DateListPlot[data, FrameLabel -> Automatic]
Out[2]=
![](assets.ru/temperature-minmax/O_2.png)
Это максимальные и минимальные значения температуры за 15-летний период.
In[3]:=
![Click for copyable input](assets.ru/temperature-minmax/In_3.png)
periodextrema = MinMax[data]
Out[3]=
![](assets.ru/temperature-minmax/O_3.png)
Это максимальные и минимальные значения температуры для каждого года.
In[4]:=
![Click for copyable input](assets.ru/temperature-minmax/In_4.png)
yearextrema =
MovingMap[MinMax,
data, {Quantity[1, "Years"], Right, Quantity[1, "Years"]}]
Out[4]=
![](assets.ru/temperature-minmax/O_4.png)
Извлеките значение экстремумов для первого года.
In[5]:=
![Click for copyable input](assets.ru/temperature-minmax/In_5.png)
yearextrema["FirstValue"]
Out[5]=
![](assets.ru/temperature-minmax/O_5.png)
Графически изобразите их колебания за 15-летний период.
In[6]:=
![Click for copyable input](assets.ru/temperature-minmax/In_6.png)
DateListPlot[yearextrema, PlotMarkers -> Automatic]
Out[6]=
![](assets.ru/temperature-minmax/O_6.png)