Моделирование малых колебаний в молекуле CO
В экспериментальных условиях молекула СО колеблется около равновесной длины с эффективной жесткостью пружины . Колебания регулируются уровнением квантового гармонического осциллятора. В дальнейшем,
является уменьшенной массой молекулы,
является естественной частотой колебаний,
представляет смещение от положения равновесия, и
является постоянной Планка.
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_100.png)
qho = -(\[HBar]^2/(2 m)) Laplacian[u[x], {x}] + (m \[Omega]^2)/
2 x^2 u[x];
Вычислим первые четыре собственных значения и нормированные собственные функции.
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_101.png)
sol = DEigensystem[qho, u[x], {x, -\[Infinity], \[Infinity]}, 4,
Assumptions -> \[HBar] > 0 && m > 0 && \[Omega] > 0,
Method -> "Normalize"]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_47.png)
Предположим, что частица находится в равной суперпозиции четырех состояний. Как следствие, волновая функция будет иметь следующий вид: .
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_102.png)
\[Psi][x_, t_] = Total[MapThread[1/2 Exp[I E t #1/\[HBar]] #2 &, sol]]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_48.png)
Определим три параметра, ,
, и
с использованием базовых блоков атомных единиц массы, таких как фемтосекунды и пм, так как полученное значение будет близко единицe.
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_103.png)
m = QuantityMagnitude[(
Entity["Element", "Carbon"][
EntityProperty["Element", "AtomicMass"]] Entity["Element",
"Oxygen"][EntityProperty["Element", "AtomicMass"]])/(
Entity["Element", "Carbon"][
EntityProperty["Element", "AtomicMass"]] +
Entity["Element", "Oxygen"][
EntityProperty["Element", "AtomicMass"]]), "AtomicMassUnits"]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_49.png)
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_104.png)
\[Omega] =
Sqrt[QuantityMagnitude[Quantity[1.86, "Kilonewtons"/"Meters"],
"AtomicMassUnit"/"Femtoseconds"^2]/m]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_50.png)
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_105.png)
\[HBar] =
QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"],
"AtomicMassUnit"*"Picometers"^2/"Femtoseconds"]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_51.png)
Функция плотности вероятности смещения задается следующим выражением: .
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_106.png)
\[Rho][x_, t_] =
FullSimplify[ComplexExpand[Conjugate[\[Psi][x, t]] \[Psi][x, t]]]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_52.png)
В качестве распределения вероятностей, интеграл над полем вещественных чисел равен 1 для всех значений
.
![Click for copyable input](assets.ru/model-small-oscillations-in-a-co-molecule/In_107.png)
Chop[Integrate[\[Rho][x, t], {x, -\[Infinity], \[Infinity]}]]
![](assets.ru/model-small-oscillations-in-a-co-molecule/O_53.png)
Визуализируем плотность вероятности с течением времени.
![](assets.ru/model-small-oscillations-in-a-co-molecule/swf_1.png)