Log-Returns von Aktienpreisen
Es wird angenommen, dass Log-Returns (Renditen) von Aktienpreisen, die mit einer geometrischen Brownschen Bewegung (im klassischen Black-Scholes-Modell) modelliert sind, normalverteilt sind. In diesem Beispiel wird diese Annahme anhand der Aktienpreise von fünf Unternehmen untersucht: Google, Microsoft, Facebook, Apple und Intel.
Rufen Sie die Aktienpreise des Jahres 2015 mit FinancialData ab.
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_99.png)
symbols = {"GOOGL", "MSFT", "FB", "AAPL", "INTC"};
prices = Table[
FinancialData[stock, {{2015, 1, 1}, {2015, 12, 31}}], {stock,
symbols}];
Berechnen Sie die Log-Returns.
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_100.png)
logreturn = Minus[Differences[Log[prices[[All, All, 2]]], {0, 1}]];
Filtern Sie die Log-Returns mit einem ARCHProcess erster Ordnung.
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_101.png)
fdata = Table[
{\[Kappa]1, \[Alpha]1} = {\[Kappa], \[Alpha]} /.
FindProcessParameters[lr, ARCHProcess[\[Kappa], {\[Alpha]}]];
MovingMap[Last[#]/Sqrt[\[Kappa]1 + \[Alpha]1 First[#]^2] &, lr, 2]
, {lr, logreturn}];
fdata = Transpose[fdata];
Vergleichen Sie mithilfe von QuantilePlot die gefilterten Daten jeder Aktie mit der Normalverteilung. Die Renditen der Aktien aller fünf Unternehmen weichen an den Enden von der Normalverteilung ab.
![](assets.de/log-returns-of-stock-prices/O_74.png)
Führen Sie einen multivariaten Normalitätstest mit BaringhausHenzeTest (BHEP) durch. Die Hypothese einer Normalverteilung ist deutlich widerlegt.
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_103.png)
htd = BaringhausHenzeTest[fdata, "HypothesisTestData"];
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_104.png)
htd["TestDataTable"]
![](assets.de/log-returns-of-stock-prices/O_75.png)
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_105.png)
htd["ShortTestConclusion"]
![](assets.de/log-returns-of-stock-prices/O_76.png)
Passen Sie die gefilterten Daten mit MultinormalDistribution und MultivariateTDistribution an.
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_106.png)
multiN = EstimatedDistribution[fdata,
MultinormalDistribution[Array[x, 5], Array[s, {5, 5}]]]
![](assets.de/log-returns-of-stock-prices/O_77.png)
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_107.png)
multiT = EstimatedDistribution[fdata,
MultivariateTDistribution[Array[x, 5], Array[s, {5, 5}], nu]]
![](assets.de/log-returns-of-stock-prices/O_78.png)
Berechnen Sie das Akaike-Informationskriterium (AIC) für die beiden Verteilungen. Das Modell der MultivariateTDistribution hat einen kleineren Wert.
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_108.png)
aic[k_, dist_, data_] := 2 k - 2 LogLikelihood[dist, data]
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_109.png)
aic[5 + 15, multiN, fdata]
![](assets.de/log-returns-of-stock-prices/O_79.png)
![Click for copyable input](assets.de/log-returns-of-stock-prices/In_110.png)
aic[5 + 15 + 1, multiT, fdata]
![](assets.de/log-returns-of-stock-prices/O_80.png)